Hi, Perl3r.

Try the following:

#!/usr/bin/perl
#
use strict;
use warnings;

$ARGV[0] or die "Usage: $0 <filename> [<filename>] ...";

my ( $template_file_name, $templateText, %hash ) = '';
my @vars = split "\n", <<END;
##location##
##rtrname##
##loop0-ip##
##frame-ip##
##frame-DLCI##
##eth0-ip##
END

while (<>) {
    chomp;
    my @fields     = split /,/;
    my $templateFN = pop @fields;

    if ( $template_file_name ne $templateFN ) {
        $template_file_name = $templateFN;
        undef $templateText;
    }

    @hash{@vars} = @fields;

    $templateText //= getTemplateText($template_file_name);
    my $templateTextCopy = $templateText;

    $templateTextCopy =~ s/$_/$hash{$_}/g for keys %hash;

    my $ofile_name = $hash{'##rtrname##'} . '.txt';

    open my $fh, '>', $ofile_name or die "$ofile_name: $!";
    print $fh $templateTextCopy;
    close $fh;
}

sub getTemplateText {
    my ($template_file_name) = @_;

    local $/;
    open my $fh, '<', $template_file_name or die "$template_file_name:
+ $!";
    $templateText = <$fh>;
    close $fh;

    return $templateText;
}
[download]

The last CSV column needs to contain the template's file name. The script can handle multiple files at once, e.g.:

processCSV.pl csv1.csv csv2.csv
[download]

The script uses Perl's 'defined-or-equals' operator to only read the template's text once, and will read in a new template if it detects a change in the template's file name (e.g., when going from csv1.csv to csv2.csv).

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.