#!/usr/bin/perl
use strict;
use warnings;

my $msg = "One bright day in the middle of the night,\n";
$msg .= "two dead men got up to fight.\n";
$msg .= "Back to Back they faced each other,\n";
$msg .= "drew their swords and shot each other.\n";
$msg .= "A deaf police man heard this noise,\n";
$msg .= "came and killed those two dead boys.\n";
$msg .= "If you don't believe this lie is true,\n";
$msg .= "ask the blind man - he saw it too!\n";

$msg =~ tr/\n//d;
for my $sentence ( split /[.!?]/ , $msg ) {
    if ( $sentence =~ /^\s*([a-zA-Z0-9]+)\s+([a-zA-Z0-9]+)\s+/ ) {
        print "$1 $2\n";
    }
}
__END__
One bright
Back to
A deaf
If you
[download]

I would do it this way. I don't know if it deserves an high grade, but it gets the job done :).

my $count = 0;
while ( $message =~ /([A-Za-z0-9]+)/g) {
    last if $count++ > 1;
    print "$1\n";
}
[download]

rnahi,
"but it gets the job done :)."

Sorry to nitpick, but actually it doesn't. The first two words were being desired of each sentence.
L~R

Updated to clarify Updated is in italics. I am still wrong because of a misinterpretation of the OP's requirements.

Did you try it?

It prints the first 2 words as defined by the OP.

I think my original post was a bit too unclear.

I am looking for at most the first two words. So it may be zero, one or two.

I've modified his code to:

my $firstWord = undef;
my $secondWord = undef;
my $i = 0;
while ($message =~ /([A-Za-z0-9]+)/g) {
    if ($i == 0) {
        $firstWord = $1;
    }
    elsif ($i == 1) {
        $secondWord = $1;
        last;
    }
    $i++;
}
[download]

which does exactly what I was looking for. I only tried to do it in one regexp.

Thanks, Marcel

This might meet the reqs?

my( $word1, $word2 ) = ( grep $_, split /[^A-Za-z0-9]+/, $message )[0,
+1]
[download]

Out of curiosity: why not just

my ($word1, $word2) = split(/[^A-Za-z0-9]+/, $message);
[download]

?

Marcel

Given the OP's examplei input

With the grep

$message = "\n +_ ABC1_\n2 3 4";
print join'|', ( grep $_, split /[^A-Za-z0-9]+/ , $message )[0,1];

ABC1|2
[download]

Without

$message = "\n +_ ABC1_\n2 3 4";
print join'|', split /[^A-Za-z0-9]+/ , $message;

|ABC1|2|3|4
[download]

You'll notice the null leading element.

The list slice is pretty redundant, but it does make it obvious that you are only wanting the first two.

---

Examine what is said, not who speaks.

"Efficiency is intelligent laziness." -David Dunham
"Think for yourself!" - Abigail

Sorry, the term phrase is probably better. I am looking for the first two words in a phrase, the phrase can end with anything and can contain newlines, etc etc.

perldoc perlre
[download]

I knew somebody was going to say this...

It's not, I have an application which has to determine by the first two words of a phrase what todo. This phrase can be anything, it might even be only one word. Examples:



my $message = "test one";
my $message = "test";
my $message = "_$ test...";
my $message = "_$ TEST..1..";
my $message = "_$\nTEST1.\n.1.2.3";
[download]

BTW: \w is not helping me here, since I do not want the underscore character.

Limbic~Region has almost got it then:

    if ( $message =~ /([a-zA-Z0-9]+)[^a-zA-Z0-9]*([a-zA-Z0-9]*)/ ) {
        print "$1 $2\n";
    }
[download]