TK Listbox help

PrimeLord has asked for the wisdom of the Perl Monks concerning the following question:

Hello monks! I have just recently started learnign how to use Tk and I am already stuck on a problem. I have a listbox that lists the textfile names in the current directory. However I can not seem to figure out how to get the users selection from that list box. Here is what I have so far.

#!perl -w

use strict;
use Tk;

# Main Window
my $mw = MainWindow->new;

# Frames
my $label3_frame = $mw->Frame;
my $files_frame = $mw->Frame;
my $exit_frame = $mw->Frame;

# File Listing Label
$label3_frame->Label(-text => "Select Files to Track")->pack(-side => 
+'left');

# File Listing Listbox
my @files;
push @files, $_ for <*.txt>;
my $listbox = $files_frame->Scrolled("Listbox",
    -scrollbars => "oe",
    -selectmode => "extended")->pack;
$listbox->insert('end', @files);

# Print Listbox Button
my @filenames;
my @selected_files = $listbox->curselection;
for (@selected_files) {
    my $file = $listbox->get($_);
    push @filenames, $file;
}
$exit_frame->Button(-text => "Files",
    -command => sub { print "@filenames\n"; })->pack;
$exit_frame->Button(-text => "Exit",
    -command => sub { exit; })->pack;

# Pack Frames
$label3_frame->pack(-side => 'top', -fill => 'y');
$files_frame->pack(-side => 'top', -fill => 'y');
$exit_frame->pack(-side => 'top', -fill => 'y');

# Main Loop
MainLoop;
[download]

The @selected_files array is never getting populated with any of the selections. Any help you can offer would be very appreciated. Thanks!

-Prime

Comment on TK Listbox help Download Code

Replies are listed 'Best First'.
Re: TK Listbox help by graff (Chancellor) on Mar 11, 2004 at 01:50 UTC
Instead of this being in the main part of your gui-creation code: `# Print Listbox Button my @filenames; my @selected_files = $listbox->curselection; for (@selected_files) { my $file = $listbox->get($_); push @filenames, $file; }` [download] you need to put those lines into a subroutine (e.g. called "print_filenames"), and maybe change the comment to read "Callback function for the "Print Listbox Button". Then, in the main part where you're declaring the other widgets, you need to actually create a Button widget that has something like "Print Chosen Files" as its text, and has this "print_files" sub as its callback. I guess you want the button you have labeled as "Files" to do the actual printing job, so something like this should work for you (not tested) -- note that the "-command" attribute of the "Files" button is being given a reference to an anonymous array, whose elements are a reference to the callback function, followed by the arg being passed to that function (the arg is the handle for the listbox where the selection will come from): `... my $listbox = $files_frame->Scrolled("Listbox", -scrollbars => "oe", -selectmode => "extended")->pack; $listbox->insert('end', @files); $exit_frame->Button(-text => "Files", -command => [ \&print_filenames, $listbox ])->pack; $exit_frame->Button(-text => "Exit", -command => sub { exit; })->pack; ... sub print_filenames { # callback for the "File" Button my $listbox = shift; my @selected_files = $listbox->curselection; for (@selected_files) { my $file = $listbox->get($_); print "$file\n"; } }` [download]	[reply] [d/l] [select]

Replies are listed 'Best First'.

Re: TK Listbox help
by graff (Chancellor) on Mar 11, 2004 at 01:50 UTC

# Print Listbox Button 
my @filenames; 
my @selected_files = $listbox->curselection; 
for (@selected_files) { 
    my $file = $listbox->get($_); 
    push @filenames, $file; 
}
[download]

Then, in the main part where you're declaring the other widgets, you need to actually create a Button widget that has something like "Print Chosen Files" as its text, and has this "print_files" sub as its callback.

I guess you want the button you have labeled as "Files" to do the actual printing job, so something like this should work for you (not tested) -- note that the "-command" attribute of the "Files" button is being given a reference to an anonymous array, whose elements are a reference to the callback function, followed by the arg being passed to that function (the arg is the handle for the listbox where the selection will come from):

...
my $listbox = $files_frame->Scrolled("Listbox",
    -scrollbars => "oe",
    -selectmode => "extended")->pack;
$listbox->insert('end', @files);

$exit_frame->Button(-text => "Files",
    -command => [ \&print_filenames, $listbox ])->pack;
$exit_frame->Button(-text => "Exit",
    -command => sub { exit; })->pack;

...


sub print_filenames
{
# callback for the "File" Button
    my $listbox = shift;
    my @selected_files = $listbox->curselection;
    for (@selected_files) {
        my $file = $listbox->get($_);
        print "$file\n";
    }
}
[download]

[reply]
[d/l]
[select]