I think you're looking for last:

#!/usr/bin/perl -w

use strict;

while (<DATA>) {
    next unless /trigger/;
    while (<DATA>) {
        if ( $_ =~ /timestamp/ ) {
            print "Found timestamp\n";
            last;
        }
    }
}

__DATA__
bar
baz
trigger
qux
timestamp
quux
quuux
trigger
quuuux
timestamp
bar
[download]

Or, to avoid nesting loops, use a range operator:

while (<DATA>) {
    if (/trigger/ .. /timestamp/) {
        if ( $_ =~ /timestamp/ ) {
            print "Found timestamp\n";
            last;
        }
    }
}
[download]

---

The PerlMonk tr/// Advocate

Yes... "last", that is it.
I even dug through my old book... I can't believe I overlooked it. What a rookie error!

I believe the command you are looking for is last

LOOP_ONE:
while (<>)
{
    next unless $condition_one;
    last LOOP_ONE;
}

LOOP_TWO:
while (<>)
{
    next unless $condition_two;
    last LOOP_TWO;
}
[download]

Be careful if reading from multiple files, as the second while will start reading from the next file if the first while exits because of EOF.

Corion pointed out that I mucked up that last paragraph.

I should have said something like this:

Be careful if reading from multiple files. You'll have to manage checking the end of each file yourself using continue. For instance, if you want to handle the first file with one while, and the second file with another, you might do something like this:

while (<>)
{
    print "$ARGV: $.: $_";
}
continue
{
    if ( eof )
    {
        close ARGV;
        last;
    }
}

print "\nnext While\n\n";

while (<>)
{
    print "$ARGV: $.: $_";
}
continue
{
    if ( eof )
    {
        close ARGV;
        last;
    }
}
print "\nDone\n";
[download]

which outputs something like this:

X:\>while_eof file1 file2
file1: 1: file1
file1: 2: line2
file1: 3: line3

next While

file2: 1: file2
file2: 2: line2
file2: 3: line3

Done
[download]

Notes:
* There is a difference between eof and eof() - see perldoc -f eof.
* The line numbers in $. are reset by doing an explicit close ARGV - see perldoc perlvar.
* If using while (<>), close ARGV won't exit the while, you'll need to do a last inside the continue.

[I hope I've been sufficiently penitent :)]