sub get_login_env {
  local %ENV;
  my $shell = shift || (getpwuid($<))[8];
  my $env = `echo env | perl -e 'exec {"$shell"} -sh'`;
  if (wantarray) {
    my @pieces = ($env =~ m/^(.*?)=((?:[^\n\\]|\\.|\\\n)*)/gm);
    s/\\(.)/$1/g foreach @pieces;
    return @pieces;
  }
  else {
    return $env;
  }
}
[download]

EDIT
I edited the RE slightly. I also should note that compared to the effort of launching a Perl process that execs itself into a login shell, a few invocations of the RE engine are unlikely to do much further damage...

UPDATE (Much later), Corion caught a silly missing | in the line that gets the environment. :-(

UPDATE 2 (Years later), as the discussion below points out, there was a silly syntax error. Fixed. Believe it or not, I used a version of this snippet for years, but that copy had been typed separately...

I downloaded this code but it doesn't work! When I try and use it the following error occurs -

syntax error at xxrcprofsub.pl line 8, near "m/^(.*?)=((?:[^\n\\]|\\.|
+\\\n)*)/gm
;"
[download]

The code to call this sub is also in a format that, novice that I am, I've not seen before -

%ENV = (%ENV, get_bash_login_env());
[download]

The ENV inside the brackets is throwing me. Is this the means by which the local (in the subroutine) %ENV is used to overwrite the existing %ENV? I've not seen this syntax before. Ronnie Cruickshank

It was missing a closing bracket just before the ";" in that line. This works:

sub get_login_env {
  local %ENV;
  my $shell = shift || (getpwuid($<))[8];
  my $env = `echo env | perl -e 'exec {"$shell"} -sh'`;
  if (wantarray) {
    my @pieces = ($env =~ m/^(.*?)=((?:[^\n\\]|\\.|\\\n)*)/gm );
    s/\\(.)/$1/g foreach @pieces;
    return @pieces;
  }
  else {
    return $env;
  }
}
[download]

Cheers, Sören

Thanks, that's a great help. Bye, Ron.