if ( date_in_range     ( $today, $start, $stop ) &&
     date_not_bad      ( $today, @notthisday   ) &&
     good_day_of_month ( $day, @dayofmon       )
{
    print "$today is the day";
}

sub date_in_range {
    my ( $today, $start, $stop ) = @_;
    return $today > $start && $today < $stop;
}
sub date_not_bad {
    my ( $today, @notthisday ) = @_;
    return $today != $notthisday[0] &&
           $today != $notthisday[1] &&
           $today != $notthisday[2]; 
}
sub good_day_of_month ( $day, @dayofmon ) {
    my ( $day, @dayofmon ) = @_;
    return $day == $dayofmon[0] ||
           $day == $dayofmon[1];
}
[download]

Chapters 12 and 14 of Code Complete also talk about various fun methods of optimizing if blocks.

Update: Added parens around 'or' condition.

ambrus++ is correct. I should know better than to post without testing.

It's very much a personal thing, but I'd opt for the latter, but I'd format it like this:

if ( $today > $start 
 and $today < $stop 
 and $today != $notthisday[0]
 and $today != $notthisday[1]
 and $today != $notthisday[2] 
 and ( $day == $dayofmon[0] or $day == $dayofmon[1] )
) {
     print "$today is the day.";
}
[download]

Agreed. The cascade of tests with and is preferable to my eye.

Just a note that there is a difference between and vs &&. The difference is order of precedence. BrowserUK used the word form so that he didn't have to worry about order of precedence so much. You can also use parentheses with either form to ensure the precedence is correct. The original example is in danger of accidentally mixing up precedence, and getting a completely wrong result.

A third alternative, in some cases, is the "quick fail." This is a series of reasons to break out of a loop or return from a subroutine early.

while (<>)
{
   next if /^\s*\#/;  # comment
   next if /^\s*$/;   # empty line
   do_the_work($_);
}
[download]

is equivalent to

while (<>)
{
   if (not /^\s*\#/ and
       not /^\s*$/)
   {
      do_the_work($_);
   }
}
[download]

--
[ e d @ h a l l e y . c c ]

I think this code is wrong, as the or operator has a lower precedence than and, so you should either change it to || or parenthisize the last two lines of the condition.

if ( $today > $start && $today < $stop ) {
  if ( $today!= $notthisday[0] ) {            
    if ( $today != $notthisday[1] ) {              
      if ( $today != $notthisday[2] ) {                
        if ( $day == $dayofmon[0] || $day == $dayofmon[1] ) { 
          print "$today is the day.";
        }
      }
    }
  }
}
[download]

I'd have to kill you if you implemented this in my code base :)

The and-composite is much better and will not draw criticism. By any chance could you put a negated grep in there for the notthisday part to make it a little more Perlish? Also, add some parens rather than relying on your knowledge of the operators as a cautionary technique.

Halley's quick fail routine is one I like a lot, but I think kesterkester's technique may be better for more complex tests, to a C programmer, that's just extra code to read through (IMHO) -- yet allows you to reuse things at the price of method call overhead. But hey, if you are reusing things, you are better off using a really cool well-tested Date module!.

Thanks all for great suggestions. I do like kesterkester's subroutine approach because I have lots of tests, some with more conditions than others, so being able to pick and choose is nice (at the expense of all the "wiring" of subroutines). I also like the quick-fail method (I tried this with unless but couldn't get my head around it) of halley, but as applied by dragonchild. And I'm glad flyingmoose won't have to kill me, and let me see what I can do with grep or even map.

—Brad
"A little yeast leavens the whole dough."

You might also want to look at Date::Manip's Events_List and Date_IsHoliday, and possibly also ParseInterval, Date_IsWorkDay, etc, as they are specifically designed to make business calendar applications easier.

sub is_day_ok
{
    my $day = shift;

    return if $today <= $start;
    return if $today >= $stop;
# Continue as necessary

    return 1;
}

if (is_day_ok($today))
{
    print "$today is the day\n";
}
else
{
    print "Nevermind.\n"
}
[download]