Not running with warnings or strict are ya!
You are assigning your $1 into the HASH slotarray, but then trying to print out the contents of the ARRAY slotarray.

# change this line, which assigns into a hash...

my $slotarray{$counter} = "$1";

# to something like this, which assigns into an array.

push( @slotarray, $1 );
[download]

use strict;
use warnings;
use Data::Dumper;

my @slot;
my $dpdrivloc = "MSL6000 Trinity";
my $regex     = qr/\Q$dpdrivloc\E:\s*(\d+)/;

#  ... open DPSLOTFILE ...

while ( <DPSLOTFILE> ) {
    if (my ($numb) = $_ =~ $regex) {
      push @slot, $numb;
    }
}

print Dumper \@slot;
[download]

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

use strict;
use warnings;

#open files here

#my $counter = 0;
my @slotarray;

while ( <DPSLOTFILE> ) {
    my $dpdrivloc = "MSL6000 Trinity";
    if ( /\Q$dpdrivloc\E:\s*(\d+)/ ) {
        #my $slotarray{$counter} = "$1";
        #print OUTFILE "$1";
        #$counter++;

        push @slotarray, $1;
    }
}

for (@slotarray) {
   #print OUTFILE "$slotarray\n";
    print OUTFILE $_,$/;
}
#close files here
[download]

The immediate problems i see with your posted code are:  my $slotarray{$counter} = "$1"; which won't work as you cannot put a my when trying to assign to a hash element; which won't work with the my in front of it. So this was changed. Second when you use for (@slotarray){ } you assign each element in @slotarray to $_ which is not the same as $slotarray and hence will print whatever was in $slotarray as many times as there are elements in @slotarray.Note that you could have also done the following:

for my $slotarray (@slotarray) {
 print OUTFILE "$slotarray\n";
}
[download]

If you are not going to be using @slotarray for anything other than printing it back out to OUTFILE why not just print while going through the while loop?

while (<DPSLOTFILE>){
  next unless /\QMSL6000 Trinity:\s*(\d+)/;
  print OUTFILE $1,$/;
}
[download]

-enlil

I tried what you had stated above and could not get it
to work.  The file looks like:
Label      Location                 Pool Name  Protection
[NFK100L2] [MSL6000 Trinity:     1] MSL6000    01/19/2004
[NFK101L2] [MSL6000 Trinity:     5] MSL6000    01/19/2004
[download]
Many times it will only be 1 line long of data but
it could be up to three.  I need to extract the 1 and 5
and put it into a new file.  Currently I only need to pull 
the first line, but in the near future I need unlimited.

This code works great for one line.  I like the idea of
just reading the line and then outputting it directly into
the file, however when doing two lines, whether I use the
\n or not, I only end up with the very last line (ie: 5).
The code that works beautifully for one line is:
#!/usr/bin/perl -w
use strict;
system ("c:\\Perl\\DataPro\\convert.bat");
open(DPSLOTFILE, "< c:\\Perl\\DataPro\\newreport.txt") or die "Can't o
+pen file: $!";
open(OUTFILE, "> c:\\Perl\\DataPro\\output.txt") or die "Can't open fi
+le: $!";
while ( <DPSLOTFILE> ) {
    my $dpdrivloc = "MSL6000 Trinity";
    if ( /\Q$dpdrivloc\E:\s*(\d+)/ ) {
    print OUTFILE "$1";
    }
}
close OUTFILE;
close DPSLOTFILE;
open (OUTFILE, "< c:\\Perl\\DataPro\\output.txt") or die "Can't open f
+ile: $!";
my $slotnumber = <OUTFILE>;
print "$slotnumber";
system("c:\\Perl\\DataPro\\omnimm -eject \"MSL6000 Trinity\" $slotnumb
+er -location \"blahblahblah\"");
close OUTFILE;
[download]
  Any comments on how to edit this to 
write out more than one slot number to the out file is
appreciated!
Thanks!  Ben

#open files here
my $counter = 0;
my %slotarray;

while ( <DPSLOTFILE> ) {
    my $dpdrivloc = "MSL6000 Trinity";
    if ( /\Q$dpdrivloc\E:\s*(\d+)/ ) {
        $slotarray{$counter} = "$1";
        #print OUTFILE "$1";
        $counter++;
    }
}

foreach my $key (keys %slotarray) {
    print OUTFILE "$key: $slotarray{$key}\n";
}
#close files here
[download]

Three things:

1. You assign your $1 into a hash but print from an array. As others have said, it's best to assign into an array, using push().
2. You create a variable, %slotarray, whose scope terminates with the end of the if block. Therefore, the variable is undefined when you go to print. You need to declare the variable at a scope visible to all uses of the variable, in this case, globally. Others have corrected your error, but not explained it.

3. You don't do actually anything with the saved data.

   Instead of saving $1 into an array, you might as well print it when you find it. But assuming you did plan to do something more sophisticated, such as sorting the elements, you don't need to print the array using a loop ... that's such a C thing to do. Perl is efficient when you deal with sets of data all-at-once, letting Perl do the iterating.

   You might use join():

   print OUTFILE join( "\n", @slotarray ), "\n";
   [download]

   Alternately, you could locally redefine the $LIST_SEPARATOR, $" :

   {
       local $" = "\n";
       print OUTFILE "@slotarray\n";
   }
   [download]