To expand upon what diotalevi said... You should do the pattern match inside the inner while loop, not in the conditional itself.

Here's how I'd rewrite your code:

while (<FH>) {
    if ( /^"\@QUERY:(.*)"/ ) {
        my $query = $1;
        while (<FH>) {
            last if /^"\@ENDQUERY"/;
            next if $_ eq '';
            print $_;
            push @{$data{$query}}, $_;
        }
    }
}
[download]

Note that this makes a HoA, rather than a HoH. Since the indices of your inner hash were simply sequential integers, an array works just as well, if not better.

PS - You don't need to backwhack quotes inside a /regex/.

(Continued.)

My code, above, will create a Hash-of-Arrays in %data. When it's done, you can iterate over the data set using code like the following:

  for my $query( sort keys %data ) {
    # get all the lines of the query at once, into an array:
    my @query_lines = @{$data{$query}};

    # or iterate over them:
    for my $qline ( @{$data{$query}} ) {
      # ... do something with the line.
    }

    # or, if you really care about the line numbers:
    for my $li ( 0 .. $#{$data{$query}} ) {
      my $qline = $data{$query}[$li];
      print "query $query, line $li: $qline";
    }
  }
[download]

Of course, the possibilities are endless; so if you are having trouble working with the data once you've read it in, we'd be happy to help.

jdporter
The 6th Rule of Perl Club is -- There is no Rule #6.

jdporter,

Update: I should've keep reading in perlreftut! The answer is here for anyone else that is still learning how to use references. Thank you all for your help.

---

Thanks for the further elaboration. For some reason, I am having a hard time understanding what is happening here:

Read more... (1170 Bytes)
----------

Using perl 5.6.1 unless otherwise noted.
Apache 1.3.27 unless otherwise noted.
Redhat 7.1 unless otherwise noted.
[download]

Or, that wonderful scalar range operator again...

my %data = ();
my $query;
while (<FH>)
{
  if (my $result = /^"\@QUERY:(.*?)"$/ .. /^"\@ENDQUERY"$/)
  {
    next if $result =~ /E/;
    if ($result == 1)
    {
      $query = $1;
      next;
    }

    push @{$data{$query}}, $_;
  }
}
[download]

My head nearly exploded looking over that. Could you just explain a little of the logic there? or point me to the needed resource?

Update: After RTFM I learned about the .. operator. Which i had read before but seeing it in this context helped bring it to light. However i'm very confused by next if $result =~ /E/; Why do you care if it has a big E in it? or did I miss something else?


___________
Eric Hodges

The '..' and '...' range operators return a number with 'E0' appended to it when the second condition matches (indicating that you are at the End of your range). That way you can tell if it is the last line with /E/ or /E0/ (e.g. if you only want the stuff in between the start and end markers), and the return value is still valid as a number. See perlop.

my $query;
while (<FH>) {
    if (my $i = /^"\@QUERY:(.*)"/.../^"\@ENDQUERY"/) {
        $query = $1, next if $i == 1;
        next if $i =~ /E/;
        print;
    }
}
[download]

Won't work. You're trying to match a multiline string on one line of input.

must... wake.. up

cLive ;-)

while (($_=<FH>) !~ /^\"\@ENDQUERY\"/) {
[download]

Easy to fix that.


while ((($_=<FH>) !~ /^\"\@ENDQUERY\"/)  or  (eof FH)) {
[download]

Update: I think you'd better write it like:

while ((($_=<FH>) !~ /^\"\@ENDQUERY\"/)  and  (not eof FH)) {
[download]