esskar has asked for the wisdom of the Perl Monks concerning the following question:

Hi friends,

i have something like this 
package lib::CGI;

use strict;
use warnings;

require CGI;
use vars qw(@ISA);

@ISA = qw( CGI );

sub redirect
{
   my ($self, $uri) = @_;

   # print "Location: $uri\n\n"; # works but is nor nice
   # CGI::redirect($self, $uri); # does not work
   # $self->redirect($uri); # endless loop
   # i need help

   exit(0);
}

[download]
How do i overload the redirect function so it is working?

Replies are listed 'Best First'.
Re: Overloading CGI::redirect
by nothingmuch (Priest) on Apr 10, 2004 at 01:04 UTC
    See perltoot and perlboot for tutorialish object oriented Perl guides, and perlobj for a reference, and lastly perlbot for more complex stuff, lots of which has to do with inheritence.

    The short answer is that $self->SUPER::method() solves your problem.

    Also, I noticed that you subclass in 3 lines. Why don't you 

    use base 'CGI';

    [download]

    instead, it's more fun ;-)

    -nuffin
    zz zZ Z Z #!perl
[reply]
[d/l]
[select]
Re: Overloading CGI::redirect
by iburrell (Chaplain) on Apr 10, 2004 at 00:10 UTC
    The way to call the superclass method is like this: 
    sub redirect {
    my ($self, $uri) = @_;
    $self::SUPER->redirect($uri);
    exit(0);
}

    [download]
[reply]
[d/l]
      Where'd you learn $self::SUPER->method? I don't think that works.
[reply]
        I got the syntax wrong. It should be $self->SUPER::method(),
[reply]
[d/l]
Re: Overloading CGI::redirect
by perlmonkey (Hermit) on Apr 10, 2004 at 05:23 UTC
    As others have said, use SUPER. A more obscure option is to alias the CGI::redirect function, something like: 
    use base 'CGI';
BEGIN {
    *cgi_redirect = \&CGI::redirect;
}

sub redirect {
    my($self,$uri) = @_;
    $self->cgi_redirect($uri);
}

    [download]
    Update:
    I forgot to mention that instead of SUPER, you can also always use the full class name. You were close, but instead of CGI::redirect($self, $uri) you should use $self->CGI::redirect($uri).

    This is useful (necessary) if you use multiple inheritance and both parent classes defined the same subroutine. So if you had: 
    package BaseA;
sub func {}

package BaseB;
sub func {};

package Derived;
use base qw(BaseA BaseB);

sub func {
    my $self = shift;
    $self->SUPER::func(); # calls BaseA::func
    $self->BaseA::func(); # same
    $self->BaseB::func(); # only way to access BaseB::func
}

    [download]
[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom