Next, [0-9] is the same as \d.

Third, the non-capturing parens are not helping you.

Boil that down and you get:

print "$1\n" if $number =~ m/
                              ^(
                                [\d.-]*
                                \d
                                [\d.-]*
                              )$
                            /x;
[download]

Oh, forgot to mention; the /x modifier helps to keep things clean and tidy looking.

If you really want it golfed, how about this:

$number =~ /^([\d.-]*\d[\d.-]*)$/ and print "$1\n";
[download]

/^([\d.-]*\d[\d.-]*)$/ looks so innocent. It is however a very inefficient regex. Because you give Perl lots of ways of matching the lone \d, it can take a relatively long time for Perl to determine there is a failure. Dropping the \d from the first character class make a huge difference:

#!/usr/bin/perl

use strict;
use warnings;

use Benchmark qw /cmpthese/;

our $re1  = qr /^[\d.-]*\d[\d.-]*$/;
our $re2  = qr /^[.-]*\d[\d.-]*$/;

our @strs = <DATA>;
    
our (@d, @a);

foreach (@strs) {
    die if /$re1/ xor /$re2/
}
 
cmpthese -1 => {
    davido  => 'my @a = map {/$re1/} @strs',
    abigail => 'my @a = map {/$re2/} @strs',
}

__DATA__
--1--2--3--4--5--6--7--8--9--0--1--2--3--4--5--6--7--8--9--0--a--2--3-
+-4--5--


            Rate  davido abigail
davido   23578/s      --    -88%
abigail 196495/s    733%      --
[download]

Abigail

The value *must* contain at least one number, but *may* also contain periods and hyphens.

But I guess the hidden requirement is that it doesn't contain anything else. You can test for that with two regexes: /\d/&&!/[^-.\d]/ (16 chars). Or, if you want to do it in one regex: /^[-.]*\d[-\d.]*$/ (18 chars).

Abigail

#!/usr/bin/perl
use strict;
use warnings;

while (<DATA>) {
  print /^(?=.*\d)[\d.-]+$/ ?
    "THIS LINE WORKS: $_" :
    "THIS LINE DOESN'T: $_";
}

__DATA__
.........---------........
...............1..........
...----1.................
-----------1-------------
.........................
-------------------------
...................-1d...
--------------------2---.
.-.-.-.-.3983943959359395
342094242.---------------
[download]

-enlil

$number = "..2341-24234233.";
if ($number =~ /\d/ && $number =~ /^([\d.-]*)$/) {
    print $1;
}
[download]

:-)

# assuming $_ has the string
#234567890123456 => 16 characters
/\d/*/^[\d.-]+$/
[download]

#23456789012345678 => 18 characters
/\d/*/^([\d.-]+)$/
[download]

japhy, thanks but I'm not sure I understand the /* and the fact that you can have, what appears to be, compounded reg exes. Anyway, I can't get it to work in


my $number = "..2314-1234123.";

if ($number =~ /\d/*/^([\d.-]+)$/ ) {
    print "$1\n";
}
[download]

If you have the time, a simple explanation would be educational. TIA

—Brad
"A little yeast leavens the whole dough."

perl -MO=Deparse

my $number = '..2314-1234123.';
if ($number =~ /\d/ * /^([\d.-]+)$/) {
    print "$1\n";
}
[download]

The original trick is multiplying the first regex result (as a scalar) by the second regex result (as a scalar). That is, 1*1 is true, but 0*1 is false.

However, since the two regexen aren't being bound to $number in your example, the code actually doesn't work. The second regex is searching $_ for matches instead.

--
[ e d @ h a l l e y . c c ]

Not really shorter, but easier to read...

  #! /usr/bin/perl -w
  use strict;

  my $number = "..2314-1234123.";

  my $stuff = qr/[0-9.-]/;
  if ($number =~ /^($stuff*\d+$stuff*)$/) {
    print "$1\n";
  }
[download]