jpfarmer has asked for the wisdom of the Perl Monks concerning the following question:

I'm currently working on making some modifications to an internal chat program for my employer. At the moment, I'm making a modification to the way that the author of each post is printed. Currently, it displays "Firstname (Location):" for all users, but I'd like to modify it so that each user can choose their own prompt format.

My end goal is to allow them to create a formatted text string with some kind of markup (like -UN- for username, -LOC- for location, etc) and then have the program stuff that with the appropriate data. My first thought was to use sprintf and simply use a regexp to replace the codes with the appropriate notation. However, this plan was dependant on being able to address the passed parameters out of order, which doesn't seem to be supported until Perl 5.8, and I'm stuck with 5.6 in my production environment.

My next attempt was to create a string with literal variable names in it (for example, $prompt = '$firstname ($location)';, but then I have to come up with a way to fill those literal variables later. Tye suggested something along the lines of s/($\w+)/"$1"/gee (that may not be exactly what he suggested, because I'm writing from memory, but I believe it is close), but that's going to add at least 30 s///'s to my program (one for each line of chat displayed), and I'd like to avoid that many additional operations since this program is run about 150 times/minute. I was warned that evaling the variable wasn't a very good idea either for safety reasons.

I feel kind of stuck at this point, because I don't really know how to fix this. I thought about using an array and, based on which values are substituted, pull out the appropriate array slices. I was thinking something like this (untested) code:

$prompt = "-RN- (-LOC-)";
@user_info = ("juser", "Joe", "3rd floor");

# Here would be some code to do create the sprintf format and
# determine the appropriate array slices
# $patten is determined to be "%s (%s)" and $slices is determined
# to be "1,2";
my $output = sprintf($pattern, @user_info[$slices]);

[download]

However, I'm not ever sure something like that can be done, and it seems like a pretty lousy way to do it even if it is possible. I can't help thinking there must be some better way that I just can't come up with.

Any suggestions you may have would be very appreciated.

Replies are listed 'Best First'.
Re: Trying to allow user-customizable prompts in a chat program
by japhy (Canon) on Apr 22, 2004 at 19:59 UTC
    I'd use a hash: 
    my %data = (
  RN => 'Joe',
  LOC => '3rd floor',
  UN => 'juser',
);

my $prompt = "-RN- \@ -LOC-";
$prompt =~ s/-([^-]+)-/$data{$1} || "-$1-"/eg;

    [download]
    Update: Here's another way: 
    %map = (
  UN => 0,
  RN => 1,
  LOC => 2,
);

my $prompt = "-RN- (-LOC-)";
my @user_info = ("juser", "Joe", "3rd floor");
my @slices;

$prompt =~ s{-([^-]+)-}{
  if (exists $map{$1}) {
    push @slices, $map{$1};
    "%s";
  }
  else { "-$1-" }
}eg;

my $output = sprintf($pattern, @user_info[@slices]);

    [download]
    _____________________________________________________
    Jeff[japhy]Pinyan: Perl, regex, and perl hacker, who'd like a job (NYC-area)
    s++=END;++y(;-P)}y js++=;shajsj<++y(p-q)}?print:??;
[reply]
[d/l]
[select]
Re: Trying to allow user-customizable prompts in a chat program
by tkil (Monk) on Apr 23, 2004 at 23:28 UTC

    To expand a bit on japhy's solution of using a hash: 

      # set this up once...
  my %cols = ( UN  => 0, RN  => 1, LOC => 2, ... );
  my $cols = do { my $tmp = join '|', keys %cols; qr/$tmp/ };

  # for each prompt to fill in:
  $prompt =~ s/-($cols)-/$user_info[ $cols{$1} ]/g;

    [download]

    This avoids the need for /e on the substitution as well as being very specific about what can be matched for template substitution.

    Depending on what else you are doing with the @user_info array, you can easily convert it into a hash by using slice assignment: 

      # once
  my @col_info = ( UN  => 0, RN  => 1, LOC => 2, ... );
  my %cols = @col_info;
  my @cols = do { my $i = 0; grep { $i = 1-$i } @col_info };
  my $cols = do { my $tmp = join '|', @cols; qr/$tmp/ };

  # for each @user_info
  my %user_info; @user_info{@cols} = @user_info;
  # now you can look up your values by name instead of position:
  print "username: $user_info{UN}\n";

  # and our substitution turns into this:
  $prompt =~ s/-($cols)-/$user_info{$1}/g;

    [download]

    A suggestion: use full-length words instead of abbreviations like "UN" and "RN". It doesn't cost that much, and it saves your users (and yourself, six months from now!) having to look them up.

[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom