in reply to Searching for a Permutation Algorithm for nPr where n != r

Algorithm::Loops makes this pretty easy: 

#!/usr/bin/perl -w
use strict;

use Algorithm::Loops qw( NestedLoops );

my @items= ( 1..6 );
my $choose= 3;
my $iter= NestedLoops(
    [   [ 0..$#items ],
        ( sub { [ $_+1 .. $#items ] } ) x ($choose-1),
    ],
);
my @choice;
while(  @choice= @items[$iter->()]  ) {
    print "@choice\n";
    # replace above line with your code
}

[download]

produces 

1 2 3
1 2 4
1 2 5
1 2 6
1 3 4
1 3 5
1 3 6
1 4 5
1 4 6
1 5 6
2 3 4
2 3 5
2 3 6
2 4 5
2 4 6
2 5 6
3 4 5
3 4 6
3 5 6
4 5 6

[download]

- tye        

Replies are listed 'Best First'.
Re: Re: Searching for a Permutation Algorithm for nPr where n != r (A::Loops)
by QM (Parson) on Apr 26, 2004 at 18:32 UTC
    The OP wanted permutations, not just combinations:
    e.g. AB, AC, AD, AE, BA, BC, BD, ...

    -QM
    --
    Quantum Mechanics: The dreams stuff is made of

[reply]

      I missed that "BA" in the list. The last page of Algorithm::Loops talks specifically about this problem and shows a few ways to do it. A fairly minor update to my code is one such way: 

      #!/usr/bin/perl -w
use strict;

use Algorithm::Loops qw( NestedLoops NextPermute );

my @items= ( 1..5 );
my $choose= 2;
my $iter= NestedLoops(
    [   [ 0..$#items ],
        ( sub { [ $_+1 .. $#items ] } ) x ($choose-1),
    ],
);
my @choice;
while(  @choice= @items[$iter->()]  ) {
    do {
        print "@choice\n";
        # replace above line with your code
    } while(  NextPermute(@choice)  );
}

      [download]

      produces 

      1 2
2 1
1 3
3 1
1 4
4 1
1 5
5 1
2 3
3 2
2 4
4 2
2 5
5 2
3 4
4 3
3 5
5 3
4 5
5 4

      [download]

      - tye        

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom