Look at DBI Recipes, and you'll find several ways of dealing with hashes.

Among them there is something like:

my $sth=$dbh->prepare($query);
$sth->execute or die $DBI::errstr;
my $array_of_hashes = $sth->fetchall_arrayref({});
for my $href (@$array_of_hashes) {
    # do something smart with $href
}
[download]

HTH

foreach $i ($$array_ref) {

That should be @$array_ref.

if($Sort == "byname") {

== should be eq.

$DB{ $$i[0] } = [ $$i[1],$$i[2],$$i[3] ];

Good enough, but consider using arrow notation instead: $i->[0].

Anyway, the same using DBIx::Simple would be:

%DB = $db
    -> query('SELECT name, height, width, date FROM mydatabase')
    -> map_arrays( { byname => 0, bydate => 3 }->{$sort} );
[download]

%DB = $db
    -> query('SELECT name, height, width, date FROM mydatabase')
    -> map_arrays($sortby);
[download]

while ($ref=$sth->fetchrow_hashref) {
[download]

You might find Data::Dumper useful for examining what data structure you have. Use fetchrow_arrayref() or fetchrow_hashref() (as others have already suggested) so that you only need to address one row at a time.

Read the DBI documentation thoroughly. It's lengthy but it'll save you debugging time, especially if you are new to Perl. Copy the examples carefully; Perl is very intolerant to typos. And remember error checking, even though I didn't here.

#!/usr/bin/perl
use strict;
use warnings;

use DBI;
use Data::Dumper;

my $Sort = 'bydate';
my %DB;

my $dbh = DBI->connect('DBI:Pg:dbname=tilrman');
my $sth = $dbh->prepare('SELECT name,height,width,date FROM foo');

$sth->execute();
while (my $row = $sth->fetchrow_arrayref()) {
  if ($Sort eq 'byname') {
    $DB{$row->[0]} = [ @{$row}[1, 2, 3] ];
  }
  elsif ($Sort eq 'bydate') {
    $DB{$row->[3]} = [ @{$row}[1, 2, 0] ];
  }
}
$sth->finish();
$dbh->disconnect();

print Data::Dumper->Dump([\%DB], ['*DB']);
[download]

# Prepare, execute, and bind to the query
my $sth = $dbh->prepare("SELECT name,height,width,date FROM mydatabase
+");
$sth->execute;
$sth->bind_columns(\$name,\$height,\$width,\$date);

my %DB;

#iterate through the recordset with fetch
while( $sth->fetch() ) {
    if($Sort eq "byname") {
        $DB{$name} = [$height, $width, $date];
    } elsif($Sort eq "bydate") {
        $DB{$date} = [$height, $width, $filename];
    }
}
[download]

Can't use string ("1") as a HASH ref while "strict refs" in use at /us
+r/local/lib/perl5/site_perl/5.8.3/i386-freebsd/DBI.pm line 511.
[download]