Perl doesn't see commas as being part of a number?

Given that it is a string that is less than suprising. In fact Perl tries its best to make a number out of the string - in fact it does find the number 1 (the bit before the first comma).....

C:\>perl -e "print '1,000,000' + 1000"
1001
C:\>
[download]

What you see is a warning as Perl knows that effectively doing an atoi()ish thing on a string may give unexpected results. Just remove the commas first and re-add them for output.

sub decommify { 
    my ( $number ) = @_;
    $number =~ tr/,//d;
  return $number
}

sub commify {
    my ( $number ) = @_;
  return undef unless $number;
    ( $number, my $dec ) = $number =~ m!([+-]?\d+)\.?(\d*)!;
  return undef unless $number;
    $number =~ s/(\d)(?=(\d{3})+(\D|$))/$1,/g if length($number) > 3;
  return $dec ? "$number.$dec" : $number;
}

print commify( decommify("1,000,001.123456789") + 1000 );

__DATA__
1,001,001.12345679
[download]

From perlfaq5:

How can I output my numbers with commas added?

This one will do it for you:

  sub commify {
      local $_  = shift;
      1 while s/^([-+]?\d+)(\d{3})/$1,$2/;
      return $_;
  }
[download]

There are a range of variations on the commify theme. That faq version is probably the worst. It is inefficient as it backtracks to do the job and also chokes on things like $1000 or 'string 123456'. The regex in my sub is one of merlyns creations but it chokes on >3 numbers after the decimal point without handling them separately. The Perl cookbook version:

sub commify {
    my $text = reverse $_[0];
    $text =~ s/(\d\d\d)(?=\d)(?!\d*\.)/$1,/g;
    return scalar reverse $text;
}
[download]

Is more more fault tolerant than the one from the faq.

cheers

tachyon

If you are merely using commas for readability, you can use underscores instead. But you can only use them in unquoted numbers, not strings.

print  1_000_000  + 1000;  # 1001000
print '1_000_000' + 1000;  # Warning!
[download]

BTW, Perl will completely ignore the underscores, so if you accidentally mistype 1_000_00_000, you'll get 100 million instead of 1 billion -- and no warning.

#!/usr/bin/perl

use warnings;
use strict;

my $num = 1_002_345;

my $total = $num + 1000;
[download]

sub commify {
    my $text = reverse $_[0];
    $text =~ s/(\d\d\d)(?=\d)(?!\d*\.)/$1,/g;
    return scalar reverse $text;
}
[download]

The point with parsing a (maybe user input) string is that there is no correct way to handle commas and dots if yuou don't take you LOCALE into consideration. The string 2,500 written by an american is two thousand five hundred, by an italian is two and a half. And such numbers can be rather ambiguous, both in reading and in input. The standard computer notation uses only the dot for the decimal part and no commas and it's in most cases unambiguous. In all other cases you'll have to rely on the locale, and you should not expect a language to do it by itself (Java does if you don't tell it; but then, how do you know which version of the system was installed on the Linux box of your Hungarian branch?)

You could always s/,// for $num though.

$num =~ s/,//;
[download]

<pedant>
  $num =~ s/,//g;
</pedant>

Sorry...