1) why/how does it skip the dupe?

It actually doesn't skip it. It's just that it is assigned as a key to a hash, and hash keys are unique, thus it overwrites the old key without doing harm.

2) what does assigning the 1 do?

It's just a random value, you could assign anything you like as a value to the hash. It's not important, as long as there's something there to make perl happy.

3) what does that 2nd line do to delete the key/value pairs of page => 1?

nothing. It now restores the AoH. Hmm, I didn't tidy up the "%uniq" hash if you thought of that.

Also, any good sources for learning how to disect a map/grep

Besides   perldoc -f grep   and perldoc -f map? Hmm. Reading Perlmonks... ;)

Cheers, Sören

Thanks again for the excellent explanation. However, my script just got a bit more complicated. How do I get rid of two dupe keys per element? See what I naively tried:

use Data::Dumper;
use strict;

my $AoH = [ { page => 'spring',
                 chap => 'spring'},
            { page => 'winter',
                 chap => 'winter'},
            { page => 'fall',
                 chap => 'fall'},
            { page => 'summer',
                 chap => 'summer'},
            { page => 'spring',
                 chap => 'spring'}
          ];

my %uniq = map { $_->{page} => ; $_->{chap} => 1 } @$AoH;
@$AoH = map { { page => $_ };{ chap=>$_ } } keys %uniq;

print Dumper ($AoH);
[download]

I doesn't work exactly the way it should and returns:

$VAR1 = [
          {
            'chap' => 'summer'
          },
          {
            'chap' => 'winter'
          },
          {
            'chap' => 'fall'
          },
          {
            'chap' => 'spring'
          }
        ];
[download]


—Brad
"A little yeast leavens the whole dough."

I think you want to have your last map return one 2-element hash ref for each unique key. Instead, you're creating two 1-element hash refs, and returning only the second one.

my %uniq = map { ($_->{page} => 1, $_->{chap} => 1) } @$AoH;
@$AoH = map { { page => $_ , chap=>$_ } } keys %uniq;
[download]

---

The PerlMonk tr/// Advocate

Here is another way, similar to hv's solution, but generalized so that you don't have to explicitly name the keys. It compares the hashes for equality - ie they must have the same set of keys, and those keys must have the same values. It does this by making a string representation of the hash. Its not so general that it would handle more complex data structures.

#!/usr/bin/perl

use Data::Dumper;

my $AoH = [ 
  { page => 'spring', chap => 'spring'},
  { page => 'spring', chap => 'spring'},
  { page => 'winter', chap => 'winter'},
  { page => 'spring', chap => 'spring'},
  { page => 'spring', chap => 'fall'},
];

my %dupes;
++$dupes{ stringify( %$_ ) } for @$AoH;;

print Dumper \%dupes;

@$AoH = grep $dupes{ stringify( %$_ ) } == 1, @$AoH;

print Dumper $AoH;

sub stringify {
  my %hash = @_;

  # explicitly name keys if you want to compare on some
  #return join '', map { $_, $hash{$_} } ( qw/ page chap / );

  # or use them all
  join '', map { $_, $hash{$_} } sort keys %hash;
}

__END__
$VAR1 = {
          'chapspringpagespring' => 3,
          'chapfallpagespring' => 1,
          'chapwinterpagewinter' => 1
        };
$VAR1 = [
          {
            'page' => 'winter',
            'chap' => 'winter'
          },
          {
            'page' => 'spring',
            'chap' => 'fall'
          }
        ];
[download]