Yeh - that figures out links pretty well..



use strict;
use Cwd 'abs_path';

my $fileinquestion = "/var/mail/";
my $realpathfor = abs_path($fileinquestion);
print "$realpathfor\n";
[download]



If you have to be out inside a system operation, the value of

pwd -P
[download]

is pretty real

Out of curiosity I tried a .. operation under win2k with AS.. it seems to work..


#!perl

use strict;
use Cwd;
use Cwd 'abs_path';

my $q = 'C:\\TEMP\\';
chdir $q;
my $dirnow = getcwd();

print "Changed dir to C:\\TEMP\n";
print "Cwd thinks I am in $dirnow\n";

chdir "..\\";

print "Changed dir up one level ..\n";
my $newdirnow = getcwd();
print "Cwd now thinks I am in $newdirnow\n";
[download]


so that might do the right thing if a user provides input including \path\..\another\path, so long as backslashes get treated correctly

Thanks - Look like it will do the trick. I need to check VMS though.

One thing I have noticed is that the directory must exist - and must actually be a directory. Feeding a file to Cwd::abs_path causes it to carp with "Not a directory".

--
I'm Not Just Another Perl Hacker

Not on my system (perl5.8.0):

$ perl -MCwd=abs_path -e 'warn abs_path("$ENV{HOME}/../slavenr/.cshrc"
+)'
/home/slavenr/.cshrc at -e line 1.
[download]

I use URI:

#!/usr/bin/perl

use strict;
use warnings;

use URI;
my $base_uri = URI->new( '/home/httpd/project/' );

while (my $path = <DATA>) {
  chomp($path);
  my $absolute = URI->new_abs( $path, $base_uri );
  printf "%s + %s: %s\n", $base_uri->canonical, $path, $absolute->cano
+nical;
}

__DATA__
../another/
subdir/
../../../etc/very/dangerous
../project/
[download]

use URI::file;
my $base_uri = URI::file->new( URI::file->cwd );

while (my $path = <DATA>) {
  chomp($path);
  my $absolute = URI::file->new_abs( $path, $base_uri );
  printf "%s + %s: %s\n", $base_uri->canonical, $path, $absolute->file
+;
}

__DATA__
../another/
subdir/
../../../some/other/place
../project/
[download]

For a more thorough discussion of what you're up against, check out some of my comments in Absolute pathnames from relative?.

Matt

If you want to demand a GNU environment, there is a GLIBC function called something like "cannonical_path" which will do all the work for you. Otherwise... ouch.

$abs_file = File::Spec->rel2abs( $_, $directory );
$canon_file = elimupdir( $abs_file );

sub elimupdir {
    my $foo = shift;
    my( $volume, $directories, $file ) = File::Spec->splitpath(File::S
+pec->canonpath( $foo ));

    my( @dur ) = File::Spec->splitdir( $directories );

    my @dar;
    foreach(@dur){
        if( $_ eq $updir ){
            pop @dar;
        } else {
            push @dar, $_;
        }
    }

    return File::Spec->catpath(
        $volume,
        File::Spec->catdir( @dar ),
        $file
    );
}
[download]

Sub is nice, here is returns relative path to current directory:

# sub file_normalize: based on https://www.perlmonks.org/?node_id=3628
+93
sub file_normalize {
 use File::Spec::Functions;
 my $dir_ref = ".";
 my $file = shift;
 $file = File::Spec->rel2abs($file);
 my( $volume, $directories, $basename ) = File::Spec->splitpath(File::
+Spec->canonpath($file));
 my @dirs_in = File::Spec->splitdir( $directories );
 my @dirs_out;
 for my $dir (@dirs_in) {
  if ($dir eq "..") {
   pop @dirs_out;
  } else {
   push(@dirs_out, $dir);
  }
 }
 return File::Spec->abs2rel(File::Spec->catpath($volume, File::Spec->c
+atdir(@dirs_out), $basename), $dir_ref);
}
[download]

Nitpicks: File::Spec::Functions doesn't need to be loaded since it isn't being used, and since File::Spec is already being used, I'd recommend File::Spec->curdir and File::Spec->updir instead of "." and "..".

But as was already mentioned in this thread, such logical cleanups have potentially major caveats. Going out to the filesystem with Cwd's abs_path and related is generally better.