I was just going to mention that "%-20s" is probably more what was wanted than "%20s" (yes, annoying how printf defaults to right-justifaction for non-numeric formats). Then I noticed no double underlines and that you assume that all of the arrays have the same number of elements. Finally, I went with "%-19s" which fits nicely on screens that are a multiple of 20 characters wide.

my @keys= sort keys %TOP;
my $format= join( " ", ("%-19s") x @keys ) . "\n";
printf $format, @keys;
printf $format, map { "=" x length($_) } @keys;
my $line= 0;
while(  grep { $line <= $#{$TOP{$_}} } @keys  ) {
    printf $format, map { def($TOP{$_}[$line]) } @keys;
    $line++;
}
sub def {
    return defined $_[0] ? $_[0] : def($_[1],"");
}
[download]

sub def { 
    return defined $_[0] ? $_[0] : def($_[1],""); 
}
[download]

Another way might be:

sub def {
  (grep defined, @_, "")[0];
}
[download]

-- Randal L. Schwartz, Perl hacker

And even smarter if the list is long (although I'm replacing something that had only two items in the list):

sub def {
  defined $_ and return $_ for @_;
  "";
}
[download]

-- Randal L. Schwartz, Perl hacker