Your clean routine will never run unless @ARGV does not contain "clean" or anything else. @ARGV in scalar context will evaluate to the number of elements in @ARGV ( that's the reason perl doesn't have or need $ARGC). The '==' comparison puts its arguments in numeric context. The numification of 'clean' is zero. Therefore you will call clean() only if @ARGV is empty.

You can detect the presence of build targets with grep {$_ eq $target} @ARGV or by @hash{@ARGV} = (); clean() if exists $hash{'clean'};, or you can have a look at the Getopt family of modules.

ExtUtils::MakeMaker is really very good at this sort of thing; it relies on make to do the heavy lifting. The trouble is that POSIX-standard make is not shipped with some OS and that many authors use gnu make extensions that other makes (standard or not) do not understand.

if (@ARGV == "clean"){ print "cleaning up dirs"; clean(); }
[download]

@ARGV is a list of command-line parameters. What you probably want to do is check the first of these parameters:

if($ARGV[0] eq "clean") { # eq, not ==, for strings
  print "cleaning up dirs";
  clean();
}
[download]

A more advanced issue (feel free to skip this bit for now, while you get your code working) is that code like this (a huge chain of if..elsif...elsif...else) is likely to be difficult to maintain, if only because large blocks of code are daunting to mess with. Instead, I'd suggest building a dispatch table. First, write a bunch of handler functions, for instance:

sub clean_handler
{
  print "cleaning up dirs";
  clean();
}

sub make_handler
{
  print "making project";
  make();
}

# ...
[download]

my %cmds = (
  'clean' => \&clean, # reference to the subroutine 'clean'
  'make'  => \&make,  # reference to 'make'
  # ...
);
[download]

my $cmd = $cmds{$ARGV[0]}; # get the coderef
&$cmd();                   # call it
[download]

Here is an example...

#Setup a Dispach table.... command => \&Dispatch_Sub
my %cmd = (clean=> \&Clean ,
           quit=>  \&Quit);

my $entry=shift; # Get user input from @ARGV or Elsewhere

#This is the Main dispatch.
# First - check to see if the user command is valid.
# If so, Dispatch (Call the corresponding sub). If not, complain.
$cmd{$entry} ? $cmd{$entry}() : print qq/no such comand $entry\n/;

sub Clean{ # This is the called DISPACH sub
   print  qq/Running clean\n/;
} 

sub Quit{
  exit;
}
[download]

Other's have pointed out why the construct you are trying to use is not quite right. I would like to point out that for what you are trying to do (read command-line parameters) you should also consider using one of the GetOpt::* modules from cpan eg: GetOpt::Long.

&$_ for map { __PACKAGE__->can($_) || () } @ARGV;
[download]