The wanted() sub gets called every time a file/dir is found. Thus the map gets run every time. This is not efficient.

The typical perl idiom for doing this sort of thing involves making an RE that uses alternation operatior | as in m/this|that|other|thing/. We can automatically generate the RE from your array and also use qr// to compile it.

++ for using strict, warnings and modules BTW.

#!perl

use strict;
use warnings;
use File::Find;

my @ext = qw(.tmp .bak .$$$ .chk .old .gid
         .fts .ftg .log .dmp .--- .prv .temp);

# build and compile an RE that uses alternation operator |
my $re = join '|', map{ quotemeta } @ext;

# compile RE. ?: avoids capture into $1 from ( )
# and the $ locks the matched ext to end of filename
$re = qr/(?:$re)$/;    

sub wanted {
    return unless -f $_;
    return unless m/$re/;
    warn "Unlinking $File::Find::name\n";
    unlink $_ or warn "\tUnlink $_ failed $!\n";  
}

find(\&wanted, '/');
[download]

Typically you want to do a dummy run without unlinking. Trust me on this ;-)

Update Fixed typo, thanks hv

I would quite likely use a hash instead of a joined OR pattern.

    my %ext;
    @ext{@ext} = (1) x @ext;
[download]

and then instead of

    return unless m/$re/
[download]

I'd put

    return unless /(\.[^.]+$)/ and $ext{$1};
[download]

ihb

A more aggressive approach is also possible, besides yours and tachyon's. The unlink call can take a list, so lets try unlinking all the unwanted files in each directory we see on the way down the tree.

#!/usr/bin/perl

use strict;
use warnings;
use File::Find;

our @ext = qw(.tmp .bak .$$$ .chk .old .gid
         .fts .ftg .log .dmp .--- .prv .temp);

sub wanted {
    my $dir = $_;
    -d && unlink map {glob "$dir/*$_"} @ext;
}
find (\&wanted, $dir);
[download]

my @ext = map "*.$_", qw( .tmp .bak .$$$ .chk .old .gid
                          .fts .ftg .log .dmp .--- .prv .temp );

unlink find(file => name => \@ext, in => '/');
[download]

find / -type f -regex '.*\.\(tmp\|bak\|\$\$\$\|chk\|old\|gid\|fts\|ftg
+\|log\|dmp\|---\|prv\|temp\)$' -exec rm \{\} \;
[download]

------------
:Wq
Not an editor command: Wq
[download]