package main; # mixin

use IO::File qw(whatever);
use Net::.....
use SomethingElse;
use EtCetera;

1;
[download]

This will put everything in the main namespace, which may be good enough for you. If, however, you want to call this from a different namespace and want everything imported there, you need some more magic than a (naive) mixin:

package Everything;

sub import {
     my $pkg = caller;
     eval qq{
          package $pkg;
 
          use This;
          use That;
          use And::So::On;
          1;
     } or die $@;
}
1;
[download]

That said, this is probably a bad idea if taken to the extreme. You'll have "namespace pollution", that is, the modules you use will fight for each other's subroutine names.

(Anyone know how to do this without the eval?)

You might be desiring what Perl calls packages and modules.

Start by creating a file called Mysubs.pm. In this file, put the following:

package Mysubs;

use strict;
use warnings;

use base qw( Exporter );
our @EXPORT = qw( fee fi fo fum );

sub fee {
    print "You called Mysubs::fee()\n";
}

sub fi {
    print "You called Mysubs::fi()\n";
}

sub fo {
    print "You called Mysubs::fo()\n";
}

sub fum {
    print "You called Mysubs::fum()\n";
}

1;
[download]

Save that file in your script's working directory for simplicity for now. ...later you'll want to do something else with it and modify @INC to deal with that, but for now just save it in the same path as the main script.

Next create another script as follows:

#!/usr/bin/perl

use strict;
use warnings;
use Mysubs;

fee();
fi();
fo();
fum();
[download]

Presto, it works. There are much more elegant constructs you can use as you get more familiar with modules and packages; exporting only those subs you need, object oriented design, and so on. But this should get you started. Our Tutorials section has a lot of good information to keep you busy for awhile. And merlyn's Aplaca book, "Learning Perl Objects, References & Modules", published by O'Reilly & Assoc. is a first class introduction and detailed course in Perl's modules and object oriented world.