@Data = sort by_projname @Data;

sub by_projname {
  return (split /\|/, $a)[1] cmp (split /\|/, $b)[1];
}
[download]

@Data = map  { $_->[0] }
        sort { $_->[1] cmp $_->[1] }
        map  { $_, [ (split /\|/)[1] ] } @Data;
[download]

   my @Data = (
         "1|someproject|active...",
         "2|somethingelse|finished..."
   );
[download]

#!/usr/bin/perl -wT
use strict;

# position to sort by
my $sortbyfield = 3;
my @input = (
        '1|2|1|4|5|6|7|8|9',
        '1|2|2|5|5|6|7|8|9',
        '1|2|0|1|5|6|7|8|9',
        '1|2|9|2|5|6|7|8|9',
        '1|2|8|3|5|6|7|8|9',
        '1|2|7|4|5|6|7|8|9',
        '1|2|6|7|5|6|7|8|9',
);

# Schwartzian Transform
my @output =
  map { $_->[0] }
  sort { $a->[1] <=> $b->[1] }
  map { [$_, getfieldvalue($_, $sortbyfield)] }
  @input;

print join( "\n", @output), "\n";

sub getfieldvalue {
        my ($line, $fieldno) = @_;
        my @items = split /\|/, $line;
        return $items[$fieldno];
}
__END__
returns (sorted by 3rd _position, arrays start at 0)

1|2|0|1|5|6|7|8|9
1|2|9|2|5|6|7|8|9
1|2|8|3|5|6|7|8|9
1|2|1|4|5|6|7|8|9
1|2|7|4|5|6|7|8|9
1|2|2|5|5|6|7|8|9
1|2|6|7|5|6|7|8|9
[download]

I would suggest thinking about what you're doing with this data, however. If you're going to be accessing bits of it more than just this time, then perhaps you should be using an array of hashes or at least and array of arrays? See perlreftut.

If you break this into an array of hashes:

my @fields = qw/id projname status submitdt assign_dt 
                total complete_dt person dept closed_dt/;
# Create my array of hashes.
foreach (@Data) {
    my %hash;
    @hash{@fields} = split /\|/, $_;
    $_ = \%hash;
}
[download]

print "The id of the project in Data[0] is $Data[0]{id}\n";
[download]

my @sorted = sort {$a->{projname} cmp $b->{projname}} @Data;

# To get the same kind of format as before ...
foreach (@sorted) {
        my %temp = %$_;
        print "@temp{@fields}\n";
}
[download]

I hope this helps

jarich

  use Sort::Fields;

  # sort on the second element (i.e. element #1)
  @sorted = fieldsort '\|', [1], @lines;
[download]

You probably want to start by looking at 1836 as this has loads of information on the subject of sorting, this is also a good paper on the subject.

/J\

I create an HoA as a holder for the data. Change the index in the sort line in the for loop.

#! /usr/bin/perl -w
use strict;

my %data;
while (my $line = <DATA>)
{
  chomp $line;
  my @array = split '\|', $line;
  my $key = shift @array;
  $data{$key} = \@array;
}

#for (sort keys %data)
for (sort {$data{$a}[0] cmp $data{$b}[0]} keys %data)
{
  print $_, '=', join (', ', @{$data{$_}}), "\n";
}

__DATA__
1|name9|blah|blah|blah
2|name8|blah|blah|blah
3|name7|blah|blah|blah
4|name6|blah|blah|blah
5|name5|blah|blah|blah
6|name4|blah|blah|blah
7|name3|blah|blah|blah
8|name2|blah|blah|blah
9|name1|blah|blah|blah
[download]

my $fieldtosort = 9; # person, for now.

my @data = <DATA>; 
my @sorted = map { $_->[0] } 
sort sortf map { [$_, split /\|/ ] } @data; 
print @sorted; 

# sort by $fieldtosort
sub sortf {
$a->[$fieldtosort] cmp $b->[$fieldtosort]; 
} 

__DATA__ 
id|projname|status|submitdt|assign_dt|total|complete_dt|person|dept|cl
+osed_dt
[download]