Unless the array is huge, it's easier to access the values directly through the for loop

$hash{"array"} = ['a','b','c','d','e'];
print for @{ $hash{ array } };

a
b
c
d
e
[download]

Actually the size of the array shouldn't matter because when foreach gets a real array perl will be smart and won't expand things in place (it uses an iterator over the AV* behind the scenes which all happens in C underneath).

$ perl -MBenchmark=timethese -e <<'EOC'
$a = [ 0 ..5_000 ];
timethese( 2_000,
  { index => sub { for( my $i = 0; $i <= $#{ $a }; $i++ ) { $b = $a->[
+$i] } },
    iterator => sub { for( @{ $a } ) { $b = $_ } } } )
EOC
Benchmark: timing 2000 iterations of index, iterator...
     index: 27 wallclock secs (21.21 usr +  0.02 sys = 21.23 CPU) @ 94
+.21/s (n=2000)
  iterator:  6 wallclock secs ( 5.39 usr +  0.00 sys =  5.39 CPU) @ 37
+1.06/s (n=2000)
[download]

#!/usr/bin/perl
use strict;
my %hash;
my $i;
$hash{"array"} = ['a','b','c','d','e'];
for ($i = 0; $i <= $#{ $hash{array} }; $i++) {
    print "$i = $hash{array}[$i]\n";
}
[download]

foreach (@{$hash{"array"}})
        {
        print "$_\n";
        }

Use $# as any other sigil. As you may or may not know, you can use ${...}, @{...}, %{...} etc when dereferecing, but often the curlies are redundant which is why you don't see them so often. In fact, $foo can be written as ${foo} (which is an often seen trick when interpolating $foo in string like "this${foo}that" where $foothat would be interpolated if the brackets weren't there).

Anyway, in your case this means that you'd use $#{$hash{array}} and @{$hash{array}} to get the last element and the array itself, respectively.

See the perlref manpage for more details. Good reading is also to be found in perlreftut, perllol and perldsc

Hope I've helped,
ihb