my $last_in_sentence = sub { $content_array[$location] =~ m/\. $/s };

if(&$last_in_sentence) { ... }
[download]

Hi!

What you need is closure. Closures are little anonymous functions that you can assign to a scalar and call repeatedly. You do that like so:

my $last_in_sentence = sub {return $content_array[$loc] =~ m/\.$/};
[...]
if (&$last_in_sentence) {
  [...]
}
[download]

Voila! Hope that helps.

--j

Closures are little anonymous functions that you can assign to a scalar and call repeatedly

Not to pick nits, but that's not exactly what a closure is. What you've described is just a standard anonymous subroutine. A closure is a bit more than that. A closure captures any surrounding lexical variables, and keeps their values between calls to the subroutine. Here's the canonical example:

sub makecounter {
  my $count = 0;
  return sub { ++$count };
}

my $counter1 = makecounter;
my $counter2 = makecounter;

for (1 .. 5) {
  print $counter1->(), "\n";
}

print $counter2->(), "\n";
[download]

Update: another small bit of clarification. Anonymous subroutines are not necessary for creating closures. Regular subroutines will cause closure around any surrounding lexical variables, too. It's not as flexible, since you only get one closed set of lexical variables, but it works the same. Here's an example:

{ # create a scope for the closure
  my $count = 0;
  sub counter { ++$count }
}

for (1 .. 5) {
  print counter, "\n";
}
[download]

#!/usr/bin/perl
#
my $expr = '$a + $b';
 
my $a = 4;
my $b = 3;
print eval $expr, "\n";
 
$a = 6;
print eval $expr, "\n";
 
if( (eval $expr) == 9 ) {
    print "eval \$expr = 9\n";
}
[download]

247.~/perl/tmp > a.pl
7
9
eval $expr = 9
[download]