in reply to coderef to an object method

You're taking the coderef fine, but you don't show us how you're using it. To use a coderef as a method, you need to can manually pass the object as the first arg. Here's an example:

  {
    package foo;
    sub new { bless {}, shift }
    sub foo { ++$_[0]{foo} }
  }

  $foo = foo->new;
  $cr = \&foo::foo;

  print $cr->($foo), "\n" for 1 .. 5;

[download]

Perhaps if you post the code where you try to use the coderef, we can give a less general answer.

Update: You can also wrap the method call in an anonymous subroutine, if you'd prefer that:

  {
    package foo;
    sub new { bless {}, shift }
    sub foo { ++$_[0]{foo} }
  }

  $foo = foo->new;
  $cr = sub { $foo->foo(@_) };

  print $cr->(), "\n" for 1 .. 5;

[download]

Update: fixed to reflect chromatic's reply

Replies are listed 'Best First'.
Re^2: coderef to an object method
by chromatic (Archbishop) on Jul 21, 2004 at 06:14 UTC
    In order to use a coderef as a method, you need to manually pass the object as the first arg.

    Not necessarily.

    #!/usr/bin/perl

use strict;
use warnings;

use Test::More tests => 2;

package Foo;

sub new { bless {}, $_[0] }

sub report { return [ @_ ] }

package main;

my $foo      = Foo->new();
my $report   = \&Foo::report;
my $moreport = $foo->can( 'report' );

is_deeply( $foo->$report( 'abc' ),   [ $foo, 'abc' ],
    'coderef should work as method on object' );
is_deeply( $foo->$moreport( 'def' ), [ $foo, 'def' ],
    '... even if returned from can()' );

    [download]
[reply]
[d/l]
      Well, if you call a CODEREF (eg. as returned by ->can()) as object method without passing the objet itself as first argument, you'll lose the object context. So, you'll not be able to access the object properties, nor call any of these methods...
[reply]

In Section Seekers of Perl Wisdom