If you wrap in parens your split RE, you capture (as though it were one of the split results) whatever matched the split regexp.

If you split using a lookahead assertion, nothing is gobbled up.

These are two different approaches that yield different results, but both deserve mentioning. I will demonstrate both, but first, the normal, common, run-of-the-mill split:

my $string = "This and that";
print "$_\n" for split /\s+and\s+/, $string;
__OUTPUT__
This
that
[download]

That was the simple, and standard case. Now for the capturing method:

my $string = "This and that";
print "$_\n" for split /\s+(and)\s+/, $string;
__OUTPUT__
This
and
that
[download]

And now for the lookahead assertion method:

my $string = "This and that";
print "$_\n" for split /(?=\s+and\s+)/, $string;
__OUTPUT__
This
 and that
[download]

That third example is the trickiest. It basically matches (and thus splits) at the point at which the lookahead assertion begins, and because lookahead assertions are only assertions, they don't gobble anything at all, and thus, everything after the split-point is preserved as-is. Use care with this method; lookahead assertions are difficult to do right in split functions. Read the docs on split for details.

Just for completeness, I want to demonstrate the lookahead assertion version with a split that has more than two resulting substrings as its outcome:

my $string = "This and that and those too";
print "$_\n" for split /(?=\s+and\s+)/, $string;
__OUTPUT__
This
 and that
 and those too
[download]

...that's pretty much what you were looking for, right? That's a great question, by the way.

print "[$_]\n"
  for split /(foo)/, 'this foo is foo ... ey';

__output__
[this ]
[foo]
[ is ]
[foo]
[ ... ey]
[download]

This doesn't work exactly as you imagined, but a captured pattern in split will be included in the resulting list.

$_ = 'abcfoodefbarghibaz';
my @parts = split /(foo)/;
print "@parts",$/
__END__
abc foo defbarghibaz
[download]

Using "foo" instead of foo seems to create the false impression that split will work with either a regular expression or an exact string. Then you see things like split ".", which should really be split /\./.

Split only takes a regex (with the confusing exception of " "), so show it that way.

I laughed out loud when Abigail-II posted this response to a question of why $string =~ "stuff" works.

Of course, with regards to split, a single quoted, single space, is a "special case."




Dave

• Tutorials
  • How to RTFM

... If the PATTERN contains parentheses, additional list elements are created from each matching substring in the delimiter.

    split(/([,-])/, "1-10,20", 3);
[download]

produces the list value

    (1, '-', 10, ',', 20)
[download]

...