There are several options; DBIx::Password is one of them, but I prefer to reinvent wheels and use an hand-made configuration singleton. I keep all the configurable values in a file readable by Config::General and limited by Class::Singleton:

#configuration file
<system>
  dsn        dbi:Oracle:dbname
  username   dbuser
  password   dbpwd
  <environment>
    ORACLE_HOME /ora92/product/9.2.1.0
  </environment>
</system>
[download]

my $conf = Configuration::Singleton->instance;
my $address = $conf->value('system/dsn');
my $user = $conf->value('system/username');
my $pwd = $conf->value('system/password');
my $environment = $conf->value('system/environment');
while ( my ($variable, $value) = each %$environment ) {
  $ENV{ uc($variable) } = $value;
}

my $dbh = DBI->connect( $address, $user, $pwd,
                        { RaiseError => 1,
                          AutoCommit => 0
                        }
) or die "$DBI::errstr";
$dbh->{FetchHashKeyName} = 'NAME_lc';
[download]

The biggest thing to make sure of is that the configuration files are writeable only by one user and readable only by one group. That group should only have as members those application users which will need to read the connection information. For example, I have a www user whose only purpose is to run the Apache process. That user would be in a group called dbi_user. The password file would be permissions 640 and owned by me. If my username is dragonchild, the permissions would be:

• dragonchild can read and write the file
• Members of the dbi_user group can read the file
• No-one else even knows the file exists.

Ideally, the directory this file is in would be 770, with the same user/group ownership.

I usually just write a little MyDB module that has one method: connect. Then any script that wants to use the database just does:

use MyDB;
my $dbh = MyDB::connect();
[download]

This method will also let you add connection pooling later without changing any code other than the MyDB module.

Here's a sample MyDB module with a connect method that lets you override any of the default connect parameters (note: I just rewrote a good chunk of this as I posted it, and haven't tested it, so...):

package MyDB;

use DBI;

my %Default =
    ( database => 'mydatabase',
      driver => 'mysql',
      hostname => 'localhost',
      port => 3306,
      username => 'someuser',
      password => 'topsecret',
      options => { AutoCommit => 1,
                   RaiseError => 0,
                 }
      );

sub connect {
    my %params = @_;
    my $connect_str=sprintf("dbi:%s:database=%s;hostname=%s;port=%s",
        $params{driver} || $Default{driver},
        $params{database} || $Default{database},
        $params{hostname} || $Default{hostname},
        $params{port} || $Default{port});
        
    return DBI->connect($connect_str,
                        $params{username} || $Default{username},
                        $params{password} || $Default{password},
                        $params{options} || $Default{options}
                     );
}

1;
[download]

Brad