Arbritrarily requireing classes.

graq has asked for the wisdom of the Perl Monks concerning the following question:

How do I avoid 'hard coded' require at the top of my module and place require A::N::Other::typeOne; inside the eval{};?

package Some::Class;

my $typeToTableLookup = {
    'typeOne' => 'classOne',
    'typeTwo' => 'classTwo',
};

require A::N::Other::typeOne;   # Remove these
require A::N::Other::typeTwo;   # two lines...

sub new
{
    my ($proto, $type) = @_;
    my $class = ref($proto) || $proto;
    die( "Note type must be specified.\n" ) unless $type;
    my $self = bless { type => $type }, $class;
    return $self;
}

sub doSomeFoo
{
    my ($self, $id) = @_;

    my $typeTableName = $$typeToTableLookup{$self->{type}}
        or die( "Type does not have a class\n" );

    my $classFile = 'A::N::Other::'.ucfirst($typeTableName);
    my $fooOb;
    eval {
        # require $classFile;   # ... and replace them here.
        $fooOb = $classFile->doSomeBar($id);
    };
    die $@ if $@;
    
    return \$fooOb;
}
[download]

Or am I missing the point (as usual :P)?

Comment on Arbritrarily requireing classes. Select or Download Code

Replies are listed 'Best First'.
Re: Arbritrarily requireing classes. by japhy (Canon) on Aug 03, 2004 at 16:03 UTC
You could say `eval "require $classFile";` _____________________________________________________ Jeff `japhy` Pinyan, P.L., P.M., P.O.D, X.S.: Perl, regex, and `perl` hacker How can we ever be the sold short or the cheated, we who for every service have long ago been overpaid? ~~ Meister Eckhart	[reply] [d/l]
•Re: Arbritrarily requireing classes. by merlyn (Sage) on Aug 03, 2004 at 16:13 UTC
`sub new { my ($proto, $type) = @_; my $class = ref($proto) \|\| $proto; ...` [download] Please note that perltoot no longer recommends such code, based in part on my rant on the subject. -- Randal L. Schwartz, Perl hacker Be sure to read my standard disclaimer if this is a reply.	[reply] [d/l]
Re: Arbritrarily requireing classes. by Gilimanjaro (Hermit) on Aug 03, 2004 at 16:14 UTC
The `eval "require $classFile;";` [download] method is the one I use often. I'd name the variable $package though, because you're not actually naming the file. I sometimes even eval a 'use', so the import get's run. Be sure to keep checking $@ afterwards though... Not doing so is asking for trouble. You may want to expand the die a bit, something like: `die "Error during dynamic require of $classFile:\n$@"` [download] This'll just make the error messages a bit clearer for ya...	[reply] [d/l] [select]
Re: Arbritrarily requireing classes. by danielcid (Scribe) on Aug 03, 2004 at 16:12 UTC
Just try: `eval{ require Test::Foo::Bar; }; your_error_handled_here();` [download] -DBC	[reply] [d/l]
Re: Arbritrarily requireing classes. by ysth (Canon) on Aug 03, 2004 at 17:08 UTC
You make it: `my $class = "A::N::Other::".ucfirst($typeTableName); (my $classFile = "$class.pm") =~ s!::!/!g; require $classFile; $fooOb = $class->doSomeBar($id);` [download] No eval required, unless you are guarding against the requested class or method not existing or the method throwing an exception.	[reply] [d/l]
Re: Arbritrarily requireing classes. by gellyfish (Monsignor) on Aug 03, 2004 at 16:43 UTC
At first glance this looks like you may be going in the same direction as Module::Pluggable - of course I may be going completely wrong there. /J\	[reply]
Re: Arbritrarily requireing classes. by broquaint (Abbot) on Aug 04, 2004 at 03:34 UTC
`use Module::Locate 'locate'; ## later ... my $className = 'A::N::Other::'.ucfirst($typeTableName); my $fooOb = eval { require( locate $className ); $className->doSomeBar($id); };` [download] See. `Module::Locate` for more info. HTH `_________ broquaint`	[reply] [d/l]