I am guessing that this code is inside a subroutine and you're calling it while $_ is aliased to a constant. Try this:

for ( "read", "only", "value" ) {
    print "$_\n";
    $_ = "test"; # blows up
}
[download]

The problem is probably concealed in your code like so:

sub foo { $_ = "test"; }

foo(); # works

for ( "read", "only", "value" ) {
    print "$_\n";
    foo(); # blows up
}
[download]

The solution is to put a local $_; at some opportune point to decouple one piece of the code from the other. The trap is that aliasing constructs like for(), map and friends do not need such treatment, but while(<FH>) does.

Yes! This was the problem. I'm not sure how far back I'm picking up constant values, but I changed the "while (<PIPE>)" to "while ($foo = <PIPE>)" and that took care of it. Thank you!

I didn't realize that whiles treated $_ differently. I'll watch that in the future...

---
A fair fight is a sign of poor planning.

:)

I first saw this in a question in the monastery a long time ago. That was a far nastier case, though: someone was getting spurious action at a distance. Turns out one of his map blocks was calling a sub containing a while(<FH>), and because map aliases $_, the function modified the values in his source array. Ouch.

Ever since, while(<FH>) used without a local has been a red flag in my mind. Always localize $_ when you use this construct. (Or use a different variable, as you did, of course.)

Makeshifts last the longest.

while (<PIPE>)
is equivalent to
while (defined($_ = <PIPE>))
so you might want to use
while (defined($foo = <PIPE>))
instead of
while ($foo = <PIPE>)
What you are using will stop when you don't expect it (such as when you read in a blank line).

I doubt that the error points to that line ( but as Aristotle points out I am wrong :-( ) Perl's error messages are on occasion out by a line or two. I highly recommend checking the return value of your opens ie:

open(PIPE, "$CommandToExecute|") or die "Can't get pipe open to $Comma
+ndToExecute: $!\n";
[download]

Sound advice, but unrelated to the problem. That omission would yield an intermittent readline() on closed filehandle, not the error the OP is seeing.

Makeshifts last the longest.

I read your reply below. It is an error I have never encountered myself but it does look like the issue:

for ( qw( This is new to me ) ) {
    print "$_\n";
    open(PIPE, "dir|") or die $!;
    while (<PIPE>) { # <--- This is the line that the error points to
        print $_; 
    }
}
__DATA__
This
Modification of a read-only value attempted at script line 4.
[download]

Learn something every day. Thanks!

cheers

tachyon