@EXPORT=qw(&Encrypt,&Decrypt);
[download]

You probably want

@EXPORT=qw(Encrypt Decrypt);
[download]

Update: ok, you have use warnings, just too late to catch that mistake.

Actually he shouldn't want to use @EXPORT at all. Use @EXPORT_OK and be explicit in the import. Always.

This avoids confusion in tracking down where a function named foo came from.

Well, that's a matter of taste. Also, one should say

use base "Exporter";
[download]

which is a better style imo than

use Exporter;
@ISA = "Exporter";
[download]

There are other style errors too in the code, like not storing $cipher in an our variable, or at least declaring it; create the $cipher object only once (if the module allows that); either not having the useless new function or converting Encrypt and Decrypt to methods; not using the one-argument bless in the new method; using strict; calling die instead of exit on an error; etc. These are, however, minor errors, and we should probably first help the OP correcting the more serious errors of the code (ie making the code work)

Sorry if this insulted you.

edit:ah yes... I would pass the sub names as bareword into the @EXPORT array.

edit2: tilly's right. it should be in @EXPORT_OK, otherwise you risk namespace collision, and as tilly said you have no idea where the sub originated from in your main program, unless you do explicit importing of sub names when you  use your module

What does your client look like? You must import the function names via

 
use Config::Confmanager qw{Encrypt Decrypt};
[download]

require Exporter;
our @ISA = ("Exporter");
[download]

Hi all,
Thanks a lot for your help.
I made the above said changes in the module. But i am not able to call the function from module to my main program.
Can you pls help me to solve.
Thanks & Regards

Package != Module != Object class

perlmod perlmodlib perlmodstyle perlboot

Your code suggests that you really want to just use a module for library routines, rather than to create an object class... you're pretty much ignoring the point of object-oriented programming by having your methods try to create disposable objects to perform single operations (and you're not storing the results of CreateEncryptDecryptObject, so it's a no-op, anyway.) Further, if your methods were actually invoked through objects, they'd have the object itself as the first item in @_, meaning that, as written, your Encrypt and Decrypt methods, would be trying to encrypt and decrypt the object reference. (And your uses of $log are going to fail... they'll be trying to use $Config::Confmanager::log which will be undefined.)

How you would use these in a program would depend on whether you go with OOP or not.

Here's one easy way with a closure and an ordinary, non-object-oriented module:

package Config::Confmanager;
use warnings;
use strict;
require Exporter;
our @ISA = 'Exporter';
our @EXPORT=qw(Encrypt Decrypt);
use Crypt::CBC; #CPAN Module For Encryption And Decryption  

{
    my $crypto = Crypt::CBC->new( {'key'       => 'passport',
                   'cipher'          => 'DES',
                   'iv'              => '$KJh#(}q',
                   'regenerate_key'  => 0,   # default true
                   'padding'         => 'space',
                   'prepend_iv'      => 0
                   });
    sub Encrypt { 
    my($encryptstring) = @_;
    my $cipherencryptstring = $crypto->encrypt($encryptstring);
    die "Could not Encrypt requested string" unless $cipherencryptstri
+ng;
    return $cipherencryptstring;
    } 

    sub Decrypt {
    my($decryptstring) = @_;
    my $cipherdecryptstring = $crypto->decrypt($decryptstring);
    die "Could not Decrypt requested string" unless $cipherdecryptstri
+ng;
    return $cipherdecryptstring;
    }
}

1;
[download]

And here's how you'd use it.

#!/usr/bin/perl

use strict;
use warnings;
use Config::Confmanager;

my $cleartext = "la dee dah";
my $encrypted = Encrypt($cleartext);
my $decrypted = Decrypt($encrypted);

print "$cleartext\n";
print "$encrypted\n";
print "$decrypted\n";
[download]

(I agree with tilly about @EXPORT_OK, but didn't change it in this example to keep it just a little closer to your original.)

I remember reading perlmod when I was trying to learn how to write modules. And I also remember the deep feeling of dread and terror it left me with. It's a great reference document, but I'm not so sure a module newbie will appreciate all the detail. Instead, I'd point new module writers to 'Simple Module Tutorial', in our very own Tutorials section.

Hmmm, okay, I update my recommendation:

Keep the whole perlmod doc handy, and at least read the Perl Modules section in it.

Tutorials can also be very effective, of course!