The system function doc it contains some chunks of code that you could put directly into a subroutine:

                   @args = ("command", "arg1", "arg2");
                   system(@args) == 0
                        or die "system @args failed: $?"

               You can check all the failure possibilities by inspecti
+ng $?
               like this:

                   if ($? == -1) {
                       print "failed to execute: $!\n";
                   }
                   elsif ($? & 127) {
                       printf "child died with signal %d, %s coredump\
+n",
                           ($? & 127),  ($? & 128) ? 'with' : 'without
+';
                   }
                   else {
                       printf "child exited with value %d\n", $? >> 8;
                   }
[download]

Update: I adapted it for a program of mine this way:

#!/usr/bin/perl

use strict ;
use warnings ;

use Carp ;

# some code here

sub check_cmd {
  my %parms = @_ ;

  croak "No commands" unless
    exists $parms{cmd} and ref($parms{cmd}) eq 'ARRAY' ;

  my @cmd = @{$parms{cmd}} ;

  $parms{onerror} = 'croak' unless exists $parms{onerror} ;
  $parms{onerror} =  lc $parms{onerror} ;
  $parms{onerror} = 'croak' unless $parms{onerror} =~ /^(croak|carp|no
+ne)$/ ;

  $parms{errormsg} = "@cmd failed" unless exists $parms{errormsg} ;

  my $result = system(@cmd) ;
  unless ($result == 0) {
    print STDERR $parms{errormsg} ;
    croak report_error($?,$!) if $parms{onerror} eq 'croak' ;
    if ($parms{onerror} eq 'carp') {
      carp  report_error($?,$!) ;
      print STDERR "Press ENTER" ;
      scalar <STDIN> ;
    }
  }

  return $result >> 8 ; # exit value
}

sub report_error {
  my ($syserr,$message) = @_ ;
  my $signal    = $syserr & 127 ;
  my $exitvalue = $syserr >> 8 ;
  my $error ;

  if ($syserr == -1) {
    $error = "failed to execute: $message" ;
  } elsif ($signal) {
    $error = "program died with signal $signal" ;
  }

  return $error ;
}
[download]

The subroutine was called like this:

    $ret = check_cmd(cmd      => [$config{cvs_command},'login'],
                     onerror  => 'none',
                     errormsg => "cvs login failed") ;

    unless ($ret == 0) {
      # do something...
    }
[download]

I hope this helps a bit

 my ($sig, $ret) = ($?&255, $?>>8);
 die "child died from signal $sig" if $sig;
 die "child exited with code $ret" if $ret;
[download]