I think I figured out what you're trying to do here. If I'm off a bit, try to use this as a base to build from. You might want to take a look at perlref, perlreftut, and perldsc to learn more about references and complex data structures.

The example below should get you started. Since it appears you want to use a subroutine to add the array to the hash, I've coded it that way.

use strict;
use warnings;
use Data::Dumper;

my %hash;

my @array1 = qw( one two three );
my @array2 = qw( four five six );
my @array3 = qw( seven eight nine );

add_arrayref_to_hashref( \@array1, \%hash, 'key1' );
print "\nafter adding array1 using key1:\n", Dumper( \%hash );

add_arrayref_to_hashref( \@array2, \%hash, 'key1' );
print "\nafter adding array2 using key1:\n", Dumper( \%hash );

# getting a bit fancier here...
my $array3ref = \@array3;
add_arrayref_to_hashref( $array3ref, \%hash, ${ $array3ref }[1] );
print "\nafter adding array3 using ${ $array3ref }[1]:\n", Dumper( \%h
+ash );

sub add_arrayref_to_hashref
{
    my ( $arrayref, $hashref, $key ) = @_;

    push( @{ ${ $hashref }{$key} }, $arrayref );
}
[download]

OUTPUT:

after adding array1 using key1:
$VAR1 = {
          'key1' => [
                      [
                        'one',
                        'two',
                        'three'
                      ]
                    ]
        };

after adding array2 using key1:
$VAR1 = {
          'key1' => [
                      [
                        'one',
                        'two',
                        'three'
                      ],
                      [
                        'four',
                        'five',
                        'six'
                      ]
                    ]
        };

after adding array3 using eight:
$VAR1 = {
          'key1' => [
                      [
                        'one',
                        'two',
                        'three'
                      ],
                      [
                        'four',
                        'five',
                        'six'
                      ]
                    ],
          'eight' => [
                       [
                         'seven',
                         'eight',
                         'nine'
                       ]
                     ]
        };
[download]

Update: Ack! I see davidj posted a very similar response while I was composing mine. His uses a slice with your actual data, while mine is more of a general example. Use whichever helps, and enjoy using refs! Extra credit: Instead of passing 3 arguments, you could eliminate the key and simply pass references to the hashref and the desired arrayref, but I'll leave that as an exercise for the reader...

I can highly recommend Data::Dumper for displaying data structures once you've got the data into variables. You're not there yet, of course, and I'm not getting how your data is supposed to be structured. Can you walk us through how your sample data should be structured, using the data you provided?

davidj

The $array_ref is the record set. One line of the record set looks like the following:
...
334 Capped 28 5034366 16777215 NULL NULL NULL
373 Capped 28 5034366 16777215 NULL NULL NULL
...
$hash_ref is an empty hash.

It should look like:
Key value = '55034366';
$VAR148 = [ [ '334', 'Capped ', 28, 16777215, undef, undef ], [ '373 ', 'Capped ', 28, 16777215, undef, undef ], ]

The following code will do what you want:


#!/usr/bin/perl
use Data::Dumper;
my %HoA = ();
my %hash_track = ();
while(<DATA>) {
    chomp($_);
    my (@stuff) = split(" ", $_);
    &fill(@stuff);
}

print Dumper(\%HoA);
sub fill() {
    my @a = @_;
    my @ar = @a[0,1,2,4,5,6,7];
    my $h = $a[3];
    $HoA{$h}[$hash_track{$h}] = [ @ar ];     
    $hash_track{$h}++; 
}

__DATA__
334 Capped 28 5034366 16777215 NULL NULL NULL 
373 Capped 28 5034366 16777215 NULL NULL NULL
[download]

output:


$VAR1 = {
          '5034366' => [
                         [
                           '334',
                           'Capped',
                           '28',
                           '16777215',
                           'NULL',
                           'NULL',
                           'NULL'
                         ],
                         [
                           '373',
                           'Capped',
                           '28',
                           '16777215',
                           'NULL',
                           'NULL',
                           'NULL'
                         ]
                       ]
        };
[download]


%hash_track is used to increment the first level %HoA array.

hope this helps,

davidj