Use Algorithm::Loops:

#!/usr/bin/perl -w
use strict;

require Text::Table;
use Algorithm::Loops qw( MapCarU );

my $t = Text::Table->new( qw( ID Name Source Type Assigment ) );
my @rows= (
    [ 1, '...', '...', '...', '...' ],
    [ 2, '...', "NA\nEU", "Emp\nEx-emp", "Active\nInactive" ],
    [ 3, '...', '...', '...', '...' ],
);
$t->load(
    map {
        MapCarU {
            [ map { defined($_) ? $_ : '' } @_ ]
        } map {
            [ split $/ ],
        } @$_
    } @rows,
);
print $t;
[download]

produces

ID Name Source Type   Assigment
1  ...  ...    ...    ...
2  ...  NA     Emp    Active
        EU     Ex-emp Inactive
3  ...  ...    ...    ...
[download]

Update: Based on blokhead's observation, the heart of the code can be made quite concise:

$t->load( map { MapCarU {[@_]} map [split $/], @$_ } @rows );
[download]

Update2: Replaced erroneous use of Filter with map.

There's a diff to add this feature to Text::Table at http://grenekatz.org/downloads/perl/Text-Table-1.103.diff complete with extensions to the tests

---

Values with newlines in them are split to the next line properly. I also added the $tb object as the return value of ->add and ->load so that method calls could be chained.

print Text::Table
      ->new( qw( ID Name Source Type Assigment ) )
      ->load( [ 1, '...', '...', '...', '...' ],
              [ 2, '...', "NA\nEU", "Emp\nEx-emp", "Active\nInactive" 
+],
              [ 3, '...', '...', '...', '...' ] );

ID Name Source Type   Assignment
1  ...  ...    ...    ...
2  ...  NA     Emp    Active
        EU     Ex-emp Inactive
3  ...  ...    ...    ...
[download]

my @lines = (
  [ 1, '...', '...', '...', '...' ],
  [ 2, '...', "NA\nEU\nThird line", "Emp\nEx-emp", "Active\nInactive" 
+],
  [ 3, '...', '...', '...', '...' ]
);

for (my $l = 0; $l < @lines; $l++) {
    next unless grep /\n/, @{ $lines[$l] };
    splice @lines, $l+1, 0, [];

    ($lines[$l][$_], $lines[$l+1][$_]) = split /\n/, $lines[$l][$_], 2
        for 0 .. $#{ $lines[$l] };
}

use Data::Dumper;
print Dumper \@lines;
[download]