My first thought was:

$text =~ s/(?:national security adviser |dr\. |doctor |condoleeza )+ri
+ce/condoleezarice/ig;
[download]

But that is not what you want. You want exact. So ... we need to get down to the tricky stuff ... ;-)

$text =~ s/(?!rice)
           (?:dr\.\ |doctor\ )?
           (?:condoleeza\ )?
           rice
          /condoleezarice/igx;
[download]

I just love trickery! :-)

This is a very neat trick. It took a few moments to work out how it works ++

cheers

tachyon

Well it works but I'm clearly way out-monked here because I don't have a clue how! Can someone enlighten me?

Well it works but I'm clearly way out-monked here because I don't have a clue how! Can someone enlighten me?

The trick lies in the zero-width assertion: It will fail if none of the following optionals match anything. (It asserts no rice, but if none of the optionals match, rice is what follows.)

I guess my answer was rather on the minimalist side. So, here is a commented version. But I won't just comment the same version I made first -- what's the fun in that? This time I'll use a positive lookahead zero-width assertion, not a negative. And I'll borrow the variables from tachyon's answer, including the job description that I somehow forgot first time around.

So, here goes:

  # Note, tachyon, we need the /i modifier on each of these as well:
  my $job_desc = qr/\b national\s+security\s+adviser \s+/ix;
  my $title    = qr/\b (?:dr\.|doctor) \s+/ix;
  my $f_name   = qr/\b condoleeza \s+/ix;
  my $surname  = qr/\b rice \b/ix;
  my $repl     = 'condoleezarice';
  $text =~ s/# Zero-width assertion: One of the options must follow:
             (?= $job_desc | $title | $f_name )

             $job_desc ? # Option 1: job description
             $title    ? # Option 2: title
             $f_name   ? # Option 3: first name

             $surname    # Surname -- not optional
            /$repl/gx;
[download]

(If the surname could match any of the optionals, this would not work. Neither would the negative lookahead, though it would fail differently. But that is a problem I'll face no sooner than I need to.)

Update: Turns out there is an implied grouping with qr//, so I have removed the explicit grouping from my code.

print "Just another Perl ${\(trickster and hacker)},"
The Sidhekin proves Sidhe did it!

$dr = qr/(?:dr\.|doctor)/;
$gn = qr/(?:condoleeza)/;
$sn = qr/(?:rice)/;

/
  $dr \s+ $sn
  |
  $dr \s+ $gn \s+ $sn
  |
  $gn \s+ $sn
/x
[download]

which can be simplified to:

$dr = qr/(?:dr\.|doctor)/;
$gn = qr/(?:condoleeza)/;
$sn = qr/(?:rice)/;
/(?:$dr (?:\s+ $gn)? | $gn) \s+ $sn/x
[download]

Don't forget to escape the . in dr. to dr\.!

You can do something like this to get your desired results Effectively we only do the substitution if we have a match in $2 as well as $1 which means we have to have "SOMETHING rice" where SOMETHING is the maximum non exclusive OR of the presented cases.....

my $jdsc   = qr/(?:national\s+security\s+adviser\s+)/;
my $title  = qr/(?:dr.|doctor)\s+/;
my $fn     = qr/(?:condoleeza\s+)/;
my $sn     = qr/rice/;
my $repl   = 'condoleezarice';

while(<DATA>){
    s{ ( ( $jdsc? $title? $fn? ) $sn ) }
     { $2 ? $repl : $1 }exig;
    print;
}
__DATA__
white rice
dr. rice 
doctor rice 
dr. condoleeza rice 
doctor condoleeza rice
condoleeza rice
national security adviser doctor condoleeza rice
[download]

Update, I prefer Sidhekins method

s/ (?!$sn) $jdsc? $title? $fn? $sn /$repl/igx;
[download]

/(?:dr\. |doctor | condoleeza )+rice\b/i
[download]

. . . in any old word

You can force that to only match as a whole word with the word boundary assertion \brice\b. Otherwise, your regex looks about right to me.

Perhaps Lingua::En::MatchNames (or one of its dependencies) is what you want?

s{((national security adviser\s+)?(dr.\s+|doctor\s+)?(condoleeza\s+)?)
  (?(?{length $1})|(?!))rice}{condoleezarice}igx
[download]