A few problems, and they're all in the "Perl will give you enough rope to hang yourself" category.... $x1 and $x2 are going to be set to the literal text "substr(20,1,3)" (for example... the 20 could be any number in the range of -180 and 180). Why would you want substr to appear as literal text?

$y1 is going to be set to the string value of the 2nd digit from the left of $i, extending for three digits to the right. That means when $i is negative, the minus sign is left off. When it's positive, the high-order digit is left off. The same problem applies to the $y2 assignment. *sigh*

$array = "array$underscore$x1......etc" looks to me like you're trying to create a symbolic reference. Don't bother, that is a road to madness. Use real references instead, or a hash whos keys are this concaucted name.

And if you did absolutely have to muck up your symbol table with symbolic references, the syntax would be ${$array}[$k] = $count;, though I'm telling you, that's not what you want to be doing in your early stages of Perl learning...and probably not even in the later stages either.

You can read up on Perl's references at perlref and perlreftut. String quoting interpolation is covered in perlop. And of course there's substr.

# This is an "array of arrays". Each row is one set of ranges,
# a pair of Xs and a pair of Ys
my @ranges = ([-180, -170, -130, -120],
              [-180, -170, -110, -105]);

# This array is going to store the counts for each row of @ranges
# It is initialized to zero for each row
my @range_counts = (0) x @ranges;

# This reads default input: file(s) on command-line or STDIN
while (<>) {
  # split the line on whitespace
  my ($x, $y) = split;
  # Count through the rows in @ranges
  for my $R (0..$#ranges) {
    # Compare
    if ($x >= $ranges[$R][0] and $x < $ranges[$R][1]
        and $y >= $ranges[$R][2] and $y < $ranges[$R][3]) {
      # Increment counter
      ++$range_counts[$R];
    }
  }
}

# Go through the rows in @ranges again, printing them and the
# corresponding count
for my $R (0..$#ranges) {
  printf "(%d..%d, %d..%d): %d\n", @{$ranges[$R]}, $range_counts[$R];
}
[download]

Thank you very much. I shall give it a go and tell you how I got on :)

I would strongly suggest you go into a little more detail about what you're trying to do and let us help you with how you might want to do it. Your requirements are a little vague.

-175 -120 
-175 -135
[download]

here is a functional program to get you started...

init a counter

open the file and read it line by line

split each line on space to get an array of the fvalue and svalue

increment the counter if fvalue is within the range AND svalue is with
+in the range

close the file
[download]

It is really easy so I hope you will find it fun to convert the above into Perl.

Good luck.

update: You can even avoid the splitting in line 3 by using a simple regexp to get the fvalue and svalue. Might result in a possible speed increase, and will eliminate one spurious variable creation.

Unless you need to do something else with all the matches at the end, I'm not sure why you'd save them all in an array. Just count. Example:

my( $x_lo, $x_hi ) = ( -180, -170 );
my( $y_lo, $y_hi ) = ( -130, -120 );

my $count = 0;

while (<>) {
  my( $x, $y ) = split;
  if ( $x >= $x_lo
    && $x <= $x_hi
    && $y >= $y_lo
    && $y <= $y_hi ) {
      $count++;
  }
}

print "$count matches.\n";
[download]

If you actually needed the matches, it's simple enough to adapt the above to stick them on an array:

my( $x_lo, $x_hi ) = ( -180, -170 );
my( $y_lo, $y_hi ) = ( -130, -120 );

my @matches;

while (<>) {
  my( $x, $y ) = split;
  push @matches, [ $x, $y ]
    if $x >= $x_lo     # slighly different syntax,
    && $x <= $x_hi     # just to mix things up. :-)
    && $y >= $y_lo
    && $y <= $y_hi;
}

print scalar(@matches), " matches.\n";
[download]

And here's a golfish version:

my( $x_lo, $x_hi ) = ( -180, -170 );
my( $y_lo, $y_hi ) = ( -130, -120 );

my @matches = 
  grep { $_->[0] >= $x_lo && $_->[0] <= $x_hi
      && $_->[1] >= $y_lo && $_->[1] <= $y_hi } 
  map [ split ], <>;
[download]