It works for me. You didn't provide a test case, so I had to write my own:

my @a = (
  [4129290, 1675967, 2412031, '41%', '/usr/bin' ],
  [4129290, 1675967, 2412031, '41%', '/usr'     ],
  [4129290, 1675967, 2412031, '41%', '/local'   ],
);
sorter(@a);

__END__
output
======
before sort: /local
Sorted by drive: /usr/bin
[download]

btw, you should use my in front of @beforeSort and @sorted_by_drive, and you'd probably be better off (due to smaller memory utilisation) to accept an array reference as an argument instead of an array, and returning an array reference, instead of the array.

Maybe you're not preparing the array properly? Here's an example:

my @df_k = split(/\n/, `df -k`);

shift(@df_k); # Remove header.

my @sorted_by_drive =
   sort { $a->[5] cmp $b->[5] }
      map { [ split(/\s+/, $_, 6) ] }
         @df_k;


use Data::Dumper ();
print(Data::Dumper->Dump(
   [    \@sorted_by_drive   ],
   [qw(  $sorted_by_drive  )],
));
[download]

Updated reply to updated question:

1) Please please please please use use strict! You're not good enough to not use it yet.

2)

sub parseIntoArraySolaris (@df)
                            ^^ what does this mean?
                               It compiles, surprisingly,
                               but it's not listed in
                               docs and it doesn't give
                               the args to the var @df.
[download]

3) Hold on, isn't [4] suppose to be a string? Why are you dividing a string by 1024? Similarly, [3] is a percentage, not an amount.

4) The function could use "some" improvement:

sub parseIntoArraySolaris {
   my @rows;
   my $element;

   foreach $element (@_) {
      my ($a, $b, $c, $d, $e, $f) = split(/\s+/, $element);
      push(@rows, [ $b/1024, $c/1024, $d/1024, $e, $f ]);
   }

   return @rows;
}
[download]

which can be rewritten as:

sub parseIntoArraySolaris {
   return map {
      my ($a, $b, $c, $d, $e, $f) = split(/\s+/, $_);
      [ $b/1024, $c/1024, $d/1024, $e, $f ]
   } @_;
}
[download]

and here's how it's used:

my @df_k = split(/\n/, `df -k`);

shift(@df_k); # Remove header.

my @beforeSort = parseIntoArraySolaris(@df_k);

my @sorted_by_drive =
   sort { $a->[4] cmp $b->[4] }
      @beforeSort;

use Data::Dumper ();
print(Data::Dumper->Dump(
   [    \@sorted_by_drive   ],
   [qw(  $sorted_by_drive  )],
));
[download]

wich can be rewritten as:

# Get data.
my @df_k = split(/\n/, `df -k`);

# Remove header.
shift(@df_k);

# Parse line.
foreach (@df_k) {
   my ($a, $b, $c, $d, $e, $f) = split(/\s+/, $_);
   $_ = [ $b/1024, $c/1024, $d/1024, $e, $f ];
}

# Sort.
my @sorted_by_drive = sort { $a->[4] cmp $b->[4] } @df_k;

# Quick way of printing for now.
use Data::Dumper ();
print(Data::Dumper->Dump(
   [    \@sorted_by_drive   ],
   [qw(  $sorted_by_drive  )],
));
[download]

Stop using prototypes. Seriously. See When to use Prototypes? for a past discussion on this, and Far More Than Everything You've Ever Wanted to Know about Prototypes in Perl for the definitive treatment.

sub parseIntoArraySolaris {
    # this is what we'll return after we parse
    my @rows;
    foreach my $line(@_){
        # here's a temporary array for each column's value
        # as we split it, we divide all the numbered
        # values by 1024
        my @cols = map {m/^[\d.-]+$/ ? $_ / 1024 : $_}
                   (split(/\s+/,$line))[0..5];

        # just for debugging I'm assuming
        # see note below about using Data::Dumper
        print "$_\n" for(@cols);

        # add our parsed data for this line onto @rows
        # this is more idiomatic than how you were doing it
        # with the $arrayCount++ thing
        push(@rows,\@cols);
    }
    # now return all the data
    return @rows;
}

sub sorter {
    # this isn't very efficient for large arrays but 
    # we're probably never doing very large data sets
    # for this problem
    my @rows = @_;

    # you might want to use Data::Dumper to do debugging
    # you just do a print "before sort: ".Dumper \@rows
    # and it'll give you a very nice dump of the data 
    # structure
    print "before sort: $rows[2]->[4]\n";

    my @sorted = sort{$a->[4] cmp $b->[4]} @rows;

    print "Sorted by drive: $sorted[2]->[4]\n";
    return @sorted;
}
[download]