It is ambiguous. You might mean shift(), or you might mean @shift. The construct @{ shift } could mean either thing. See, for example:

use strict;
use warnings;

$, = "\t";

my @foo = qw/this that/;

print @{ foo }, "\n";

my @shift = qw/those these/;

print @{ shift }, "\n";

mysub( [qw/them theirs/] );

sub mysub {
    print @{ shift }, "\n";
    print @{ shift() }, "\n";
}
[download]

Compare

my @shift;
@{shift} = ( 0, 8, 8, 7.5, 8, 8.5, 0 );

my @weekday = qw(sun mon tue wed thu fri sat);
for (0..$#shift) {
  printf "On %s I work %s hours", $weekday[$_], $shift[$_];
};
[download]

against your function. @{STRING} is a way to access the array variable @STRING, at least as long as no strict 'refs' is in effect. For example the stupid idea to access a variable by its name could be implemented like that. The conflict arises because Perl and perl don't know whether you meant the string "shift" or the function shift, so it doesn't know what to do, and decides for one of the two but warns you of the other possibility.

The other syntax - the one perl is guessing wrong - is @{foo} being a form of the array @foo. Perl is not looking first for a builtin function there, but a bareword.

You can use parens as you did, or place a harmless operator in front of the shift.

my @shift = qw/a shifty array/;
sub foo {
    print @{shift};
    my @vars = @{+shift};
    print @{vars}
}
foo [qw/A mere example/];
__END__
[download]

A very idiomatic way of breaking ambiguity is to use the no-op unary +.

my @foo = @{+shift};
print +(split)[2];
$hash{+lc}++;
# etcetera
[download]

perl -we'sub foo{66}; die @{ foo }'
[download]

Compare once again to

perl -we'die shift =>1' 1
perl -we'die shift() =>1' 1
[download]

It might be worth noting that the ${foo} syntax is used in interpolation to separate variable name from following text when necessary. Thus,     print "bar$foo" . 'baz'; can be written     print "bar${foo}baz";

ihb

Read argumentation in its context!