See also (Golf) Tic Tac Toe.

Okay, here's my take.

• my board is some kind of a 2D array.
• 'x' are 1.
• 'o' are -1.
• empty is 0.

we look for an absolute 3. But I'm sure there is a more mathematical way for this:

my @board;
while (<DATA>) {
        chomp;
        push @board, [split / /];
}

for my $i (0 .. 2) {
        my ($t1, $t2, $t3, $t4) = (0,0,0,0);
        for my $j ( 0 .. 2 ) {
                $t1 += $board[$i][$j];
                $t2 += $board[$j][$i];
                $t3 += $board[$j][$j];
                $t4 += $board[2 - $j][$j];
        }
    
        if (abs($t1) == 3 || abs($t2) == 3 
                || abs($t3) == 3 || abs($t4) == 3) {
                print "Win.\n";
                last;
        }
}


__DATA__
1 0 1
-1 1 -1
1 0 1
[download]

If you take each 3x3 game grid and flatten it to a string of nine characters, this can be solved with a regexp. This particular method of solving it wasn't really touched upon in (Golf) Tic Tac Toe, but works great. The conversion of a 3x3 grid to a single flat string is trivial, so I'll just demonstrate the regexp portion of the solution.

The regexp can be expressed in a way that tests for one of four conditions. I started out with a slightly more complex regexp, and then was able to see the forest through the trees, and found a way to boil it down to this common denominator.

In the following snippet, I never placed any 'o's because I wanted to keep it visually clear what was going on. The hyphens could be replaced with x's and o's as though a real game were being played, and the regexp will discover whether X or O wins. I just wanted to show each of the winning possibilities, so I used hyphens to isolate X.

Here's the code:

use strict;
use warnings;

# Assume that the 3x3 AoA has been flattened to a single string.
# Each string, therefore, equates to a single game.

my @games = (   "x---x---x",    # Diag from top left. 1
                "--x-x-x--",    # Diag from top right. 3
                "x--x--x--",    # Vert from top left. 2
                "xxx------",    # Horiz from top left. 4
                "---xxx---",    # Horiz from mid left. 4
                "------xxx",    # Horiz from bottom left. 4
                "-x--x--x-",    # Vert from top mid. 2
                "--x--x--x"  );
            

my $i;
foreach my $game ( @games ) {
    print "Game ", ++$i, "\t";
    if ( $game =~ m/ 
                    ([xo])
                    (?:
                         (?:...\1){2}
                      |  (?:..\1){2}
                      |  (?:.\1){2}
                      |  \1{2}(?=(?:...){0,2}$)
                    )
                   /ix ){
        print "$1 wins.\n";
    } else {
        print "no winner\n";
    }
}
[download]

Update:
Here's a golfier version that uses the same solution technique:

print m/([xo])((...\1){2}|(..\1){2}|(.\1){2}|\1{2}(?=(...){0,2}$))/i?
"$1 wins.\n":"No winner.\n" foreach qw/x---x---x --x-x-x-- x--x--x-- 
xxx------ ---xxx--- ------xxx -x--x--x- --x--x--x x---x-x--/;
[download]

Update2: Fixed a problem that would allow misaligned 3-in-a-rows to win when they shouldn't.

for ($i = 0; $i < 3; $i++) {
    if ($b[$i][0] == $m && $b[$i][1] == $m && $b[$i][2] == $m) { &win(
+$m); }
    if ($b[0][$i] == $m && $b[1][$i] == $m && $b[2][$i] == $m) { &win(
+$m); }
}
if ($b[0][0] == $m && $b[1][1] == $m && $b[2][2] == $m) { &win($m); }
if ($b[0][0] == $m && $b[1][1] == $m && $b[2][2] == $m) { &win($m); }
[download]

@m = (0,1,2, 3,4,5, 6,7,8, 0,3,6, 1,4,7, 2,5,8, 0,4,8, 2,4,6);
for ($i = 0; $i < 22; $i += 3)
    { &win($t) if @g[@m[$i]] == $t && @g[@m[$i+1]] == $t && @g[@m[$i+2
+]] == $t; }
[download]