Re: loop thru 3-element array?

anadem,
Perl6 is going to make this a lot easier :-)
I have been fascinated with iterators lately, so this mildly tested code can easily be changed to iterate by any quantity specified.

#!/usr/bin/perl
use strict;
use warnings;

my @array = 0 .. 30;
my $next = by_groups_of( 3, @array );

while ( my @group = $next->() ) {
    print "@group\n";
}

sub by_groups_of {
    my $by = shift;
    return sub { () } if ! $by || $by =~ /\D/ || ! @_;
    my @list = @_;  # Make a copy in case it changes

    my $end = $#list;
    my $pos = 0;
    my $done;

    return sub {
        return () if $done;
        my $stop = $pos + $by - 1 > $end ? $end : $pos + $by - 1;
        my @sub = @list[ $pos .. $stop ];
        $pos += $by - 1;
        $done = 1 if $stop == $end;
        return @sub;
    }
}
[download]

Cheers - L~R

Update: Also see this node if you need to have modifications to the looping variables modify the array as well

Comment on Re: loop thru 3-element array? Download Code

Replies are listed 'Best First'.
Re^2: loop thru 3-element array? by kelan (Deacon) on Sep 28, 2004 at 14:23 UTC
Since you're making a separate copy of the list that gets passed in anyway, you could also use the `splice` trick that merlyn showed above, and get rid of all the arithmetic. `sub by_groups_of { my $by = shift; return sub { () } if ! $by \|\| $by =~ /\D/ \|\| ! @_; my @list = @_; # here's the copy. we're safe to splice return sub { splice @list, 0, $by }; }` [download]	[reply] [d/l]