Probably the quickest way I can think of would be to use one of the Digest::* modules, such as Digest::MD5 to compute a digest of the two files, and compare those. Taking from the sample code of the Digest::MD5 module, the following (*untested*) code might do something along the lines of what you wish. (Filenames would be provided on the command line.)

#!/usr/bin/perl -w
use strict;
use Digest::MD5;

if (! scalar(@ARGV)) {
    print <<USAGE;
Usage:
    $0 file1 file2 ... fileN

USAGE
    exit;
}

my (%md5sums);
foreach my $filename (@ARGV) {
    open(FILE, $filename) or die("Can't open '$filename': $!");
    binmode(FILE);
        my $digest = Digest::MD5->new->addfile(*FILE)->hexdigest;
        $md5sums{'by-name'}{$filename} = $digest;
        push(@{$md5sums{'by-digest'}{$digest}}, $filename);
    close(FILE);
}

print "By checksum:\n";
foreach my $digest (sort(keys(%{$md5sums{'by-digest'}}))) {
    print $digest, ": \n";
    foreach my $filename (sort(@{$md5sums{'by-digest'}{$digest}})) {
        print "\t", $filename, "\n";
    }
}
print "\n";
print "By filename:\n";
foreach my $filename (sort(keys(%{$md5sums{'by-name'}}))) {
    print $md5sums{'by-name'}{$filename}, ': ', $filename, "\n";
}
[download]

                   $checksum = do {
                       local $/;  # slurp!
                       unpack("%32C*",<>) % 65535;
                   };
[download]

File::Compare

or

compare( 'invoices.txt', 'invoices.bak' );

sub compare
{
    local *FH_A;
    local *FH_B;
    open FH_A, "< $_[0]\0" or die "Can't open $_[0] for reading: $!";
    open FH_B, "< $_[1]\0" or die "Can't open $_[1] for reading: $!";
    binmode FH_A or die "Can't binmode $_[0]: $!";
    binmode FH_B or die "Can't binmode $_[1]: $!";

    local $/ = \ 4096;
    1 while <FH_A> eq <FH_B>;
    return eof *FH_A and eof *FH_B;
}
[download]