The bottom line is that, logically, nothing requires you to turn strict off, with it on, you still can do everything, and much more safer.

You say. Try exporting symbols from one package to another like Exporter for example. AUTOLOADing is another place they have value. There *are* uses for symbolic references. With strict on *you can't do everything*. But realistically your attitude is fine. As they say, if you don't know when it is appropriate to use a symbolic reference you should not be using them.

Try exporting symbols from one package to another like Exporter for example.

The code below demonstrates a very simple exporting mechanism within the confines of strict

use strict;
use warnings;
use warnings::register;

use Symbol 'qualify_to_ref';

sub import {
  my $cur  = shift;
  my $dest = caller;

  for my $g (grep $cur->can($_),  @_) {
    warnings::warnif("sub '$g' already exists in $dest") and next
      if $dest->can($g);

    my($dest, $src) = map qualify_to_ref("$_\::$g"), $dest, $cur;
    *$dest = *$src;
  }
}
[download]

One might point out that the code in Symbol doesn't use strictures, but much of this could quite easily be done within its confines, however the code would necessarily be more verbose. If someone can find code that they believe can't be done within strictures then I shall quite happily rise to the occassion :)
HTH

_________
broquaint

Using a module that does not use strict just proves the point. We can cut and paste the relevant functions from Symbol into your code and then guess what? So the question is can you rise to the occasion ;-)

package Foo;

use strict;
use warnings;
use warnings::register;

sub foo { print "Foo!\n" };

sub import {
  my $cur  = shift;
  my $dest = caller;

  for my $g (grep $cur->can($_),  @_) {
    warnings::warnif("sub '$g' already exists in $dest") and next
      if $dest->can($g);

    my($dest, $src) = map qualify_to_ref("$_\::$g"), $dest, $cur;
    *$dest = *$src;
  }
}

# This is what we need from Symbol to provide the qualify_to_ref funct
+ion

my %global = map {$_ => 1} qw(ARGV ARGVOUT ENV INC SIG STDERR STDIN ST
+DOUT);

sub qualify ($;$) {
    my ($name) = @_;
    if (!ref($name) && index($name, '::') == -1 && index($name, "'") =
+= -1) {
    my $pkg;
    # Global names: special character, "^x", or other. 
    if ($name =~ /^([^a-z])|(\^[a-z])$/i || $global{$name}) {
        $pkg = "main";
    }
    else {
        $pkg = (@_ > 1) ? $_[1] : caller;
    }
    $name = $pkg . "::" . $name;
    }
    $name;
}

sub qualify_to_ref ($;$) {
    return \*{ qualify $_[0], @_ > 1 ? $_[1] : caller };
}

1;

__DATA__
Can't use string ("main::foo") as a symbol ref while "strict refs" in 
+use at c:/Foo.pm line 39.

# test script

#/usr/bin/perl
use lib '/blah';
use Foo 'foo';
foo();
[download]

cheers

tachyon