You seem to expect to get the keys out of the hash in the same order you declared them. You won't. Hash keys are unsorted. You need to apply a sort if you need them in a specific order, or perhaps use an array of arrays data structure which would preserve the order.

Hashes are not sorted. They're designed for direct data lookup, not ordering. If order is important to you, use an array (or sort the keys before you use them).

#!/usr/bin/perl
use strict;
use Data::Dumper;
my %HoTypes = my @HoTypes = (
    'PythonQuestions' => [ '[PythonQuestions|Python Questions]', 318, 
+3, 10 ],
    'OffTopics'       => [ '[OffTopics|Off Topic Post]',         500, 
+3, 10 ],
    'notes'           => [ 'Notes',                              283, 
+3, 20 ]
);

# retrieve the keys in the original order
@HoTypes = @HoTypes[map { $_ % 2 ? () : $_ } 0..$#HoTypes];

# and use the keys recorded in the array
for my $T ( @HoTypes ) {
        my $nodeStr = $HoTypes{$T}[0];
        print "$T -> $nodeStr\n";
}
[download]

In a similar vein to Roger's post, if you want to maintain order, then use a list. You could use a list of hashes of two keys. One key points to the label/name, the other to the data you are looking after:

my @type = (
  {
     name => 'PythonQuestions',
     data => [ '[PythonQuestions|Python Questions]', 318, 3, 10 ],
  },
  {
     name => 'OffTopics',
     data => [ '[OffTopics|Off Topic Post]', 500, 3, 10 ],
  },
  {
    name => 'notes',
    data => [ 'Notes', 283, 3, 20 ],
  },
);

for my $t( @type ) {
  print "$t->{name} -> $t->{data}[0]\n";
}
[download]

The main question is whether or not you need to use the hash for lookups. E.g., if you never need to find out what $HoTypes{$thing} points to, for some value of $thing, if all you ever do is iterate over all the keys in a loop, you can get away with a list.

Sometimes a hash is more trouble than it's worth.

my %HoTypes = (
    'PythonQuestions' => [ '[PythonQuestions|Python Questions]', 318, 
+3, 10, 0 ],
    'OffTopics'       => [ '[OffTopics|Off Topic Post]',         500, 
+3, 10, 1 ], 
    'notes'           => [ 'Notes',                              283, 
+3, 20, 2 ]
);
[download]

for my $T ( sort { $HoTypes{$a}[-1] <=> $HoTypes{$b}[-1] } keys %HoTyp
+es ) {
        my $nodeStr = $HoTypes{$T}[0];
        print "$T -> $nodeStr\n";
}
[download]

cLive ;-)