First, you hardly ever need an extra counter when you loop in Perl. That is a hold over from other languages, i had the same bad habit myself when i started Perl. Second, since you know which <trans> you want, the one with kool="kool", then you don't need to worry about counting them: just "ask" for the <trans> tag with attribute kool that is set to "kool". Third, use the right tool for the right job. In this case, XML::Twig is the Vorpal Blade you seek:

use strict;
use warnings;
use XML::Twig;
 
my $twig = XML::Twig->new(pretty_print => 'indented');
my $data = do {local $/;<DATA>};
$twig->parse($data);
 
my $root  = $twig->root;
my @trans = $root->children;
 
for my $trans (@trans) {
    next unless $trans->att('kool') eq 'kool';
 
    my $item = XML::Twig::Elt->new(item => { id => 'maxis'});
 
    my $assignee = XML::Twig::Elt->new(assignee => 'Jill')
        ->paste(last_child => $item);
 
    my $status = XML::Twig::Elt->new(status => 'con')
        ->paste(last_child => $item);
 
    $item->paste(last_child => $trans);
}
 
$twig->print;
 
__DATA__
<opt>
 <trans kool="max">
  <item id="legas">
    <status>contacted</status>
    <assignee>jack</assignee>
  </item>
 </trans>
 <trans kool ="kool">
  <item id="gas">
    <status>contacted</status>
    <assignee>jack</assignee>
  </item>
 </trans>
</opt>
[download]

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

I see now. Also I am a new in Perl, so I have the same problem as you before. I understand when using the  next unless $trans->att('kool') eq 'kool'; it is easy to do it instead to have a counter.
Thanks for your advise. I really appreciated.

Maxim