#! perl -slw
use strict;

sub t{
    ## Strict complient lexical access to a glob
    our %hash; 

    ## Localise it for use as an alias 
    ## to an inbound hash ref    
    local *hash =  shift; 

    ## no need to dereference the hashref
    print "$_ => $hash{ $_ }" for keys %hash;
}

my %hash = ( 'A'..'Z' );

t( \%hash );
__END__
P:\test>test
S => T
A => B
O => P
W => X
K => L
Y => Z
E => F
Q => R
M => N
C => D
I => J
G => H
U => V
[download]

my %hash = (1 => 2, 3 => 4);
my $ref = \%hash;
my $alias = $ref;
print "hash = ", %hash, "\n";
print "ref hash = ", %$ref, "\n";
print "alias hash = ", %$alias, "\n";
[download]

hash = 1234
ref hash = 1234
alias hash = 1234
[download]

Nah, that's still a reference. I want a %hash to be an alias to the referent, not a $scalar to keep the same reference.

Thanks

So you want to be able to do something like this:

my $ref = {thing => 'value', otherthing => 'other'};
%alias_to_ref = ;# insert magical code here
                 # to create a hash which will
                 # still modify $ref

$alias_to_ref{thing} = 'newvalue';

print $ref->{thing};
[download]

And have that output 'newvalue'? If that is what you want, you probably could do it with a tied hash. See Below:

#!/usr/local/bin/perl -w
use strict;

my($ash) = {thing => 'other', and => 'antoher'};

my(%hash);

tie %hash, 'MyHash', $ash;

$hash{thing} = 'new';

print $ash->{thing}."\n";

package MyHash;
require Tie::Hash;
@MyHash::ISA = qw(Tie::StdHash);

sub STORE
{
    my $me = shift;
    my $key = shift;
    $me->{$key} = shift;
}

sub TIEHASH
{
    my $package = shift;
    my $ref = shift;
    return bless($ref, $package);
}
[download]

This outputs 'new'.

May the Force be with you

use Lexical::Alias ('alias');
my $ref = { a => 'b', c => 'd' };
my %hash; alias %{$ref}, %hash;
print $ref->{'a'}; $hash{'a'} = 'e'; print $ref->{'a'};
[download]

$ perl alias.pl
b
e
[download]

Cheers