Q1. How do I make the constructor return all three data structures, $hashref, @array, and $arrayref when invoked. Is it possible? I understand that only one of these three can be returned by the constructor and not all together. Correct?

Q2. I guess with $object1,$object2,$object3, I am creating three different objects. Right? Is there a way by which I create just one object of ABC and through this object I am able to manipulate data in all three data structures of, $hashref, @array, and $arrayref.

Q3. Do I need to create three different sets of get() and set() functions each to manipulate $hashref, @array, and $arrayref respectively by creating their objects first, ie $object1,$object2,$object3 ?

Q4. I understand I can manipulate $hashref, @array, and $arrayref only through access functions like get() and set() and not directly like $object1->$hashref or something like it, am I correct?

Q5. (...) Perhaps, the nested structure might make the program slower, yes/no?

The subroutine can have whatever logic you want coded into it.
You can have multiple encapsulated private data objects (array, hashes, scalars etc),
and even build in permissions or validation logic to certain actions or attributes.
The AUTOLOAD routine can be coded to handle most of the simple accessors, saving
you the trouble of coding them all, and your script from compiling them all each run.

This also helps force people to access your object through the accessor methods rather than
getting at the data itself, like what happens with blessed hashes or arrays.

package Bill;
use strict;
use warnings;

our ( $AUTOLOAD );

sub AUTOLOAD
{
    my ( $self, $newval ) = @_;

    no strict q{refs};

    if( $AUTOLOAD =~ /.*::get_(.+)/ )
    {
        my $attr = $1;  # Class Attribute name.
   
        *{$AUTOLOAD} = sub { $_[0]->( q{get}, $attr ) }; #cache

        return $self->( q{get}, $attr );
    }
    elsif ( $AUTOLOAD =~ /.*::set_(.+)/ )
    {
        my $attr = $1;

        *{$AUTOLOAD} = sub { $_[0]->( q{set}, $attr, $_[1] ) }; #cache

        return $self->( q{set}, $attr, $newval );
    }
}

sub new
{ 
    my ( $class, $args ) = @_;
  
    my %attribs; # Hold and ecapsulate all object attribs.

    my @protected_attribs = qw( userid access_level );

    # This means that rather than being able to get at object 
    # attribs like this...
    #   $self->{obj_attrib}
    # you have to do this...
    #   $self->( 'get', 'obj_attrib' );
    #   $self->( 'set', 'obj_attrib', 'new_value' );
    # OR through use of the AUTOLOAD routine...
    #   $self->get_obj_attrib;
    #   $self->set_obj_attrib( 'new_value' );
    my $self = sub
    {
        my ( $cmd, $attr, $newval ) = @_;

        if ( $cmd eq q{set} )
        {
            unless ( scalar grep { $attr eq $_ } @protected_attribs )
            {
                $attribs{$attr} = $newval
            }
        }

        return $attribs{$attr};
    };
   
    $self = bless $self, $class;
    #-----------------------------------------

    # Do any initialization that is needed for the objects data
    $attribs{dbh} = $args->{dbh};

    return wantarray ? ( 1, $self ) : $self;

} # END new
[download]

Damian Conway's Object Oriented Perl book, has more on this type of object structure.
One of the best Perl books I have ever read.

Updated: Added link for Damian's book.

Hope that helps,
Wonko

As have already figured out in your Q5, what you usually want to do is create something that contains three objects. Very typically this is a hash in Perl, especially if each element object fulfills a role. So Human->new() may call Arm->new() and Leg->new() twice each; and put the resulting members in its fresh new $self->{right_arm}, $self->{left_arm}, $self->{right_leg}, and $self->{left_leg}.

You would then access the nested objects via indirection, which is a bit slower but not significantly so for most purposes. For example:

$person = Human->new();

$person->{right_arm}->grasp("banana");   # not through accessor
$person->get_right_arm->grasp("banana"); # through accessor

# or, you might write accessors like this too if you think they'd be u
+seful:

$person->arm("left")->grasp("orange");
[download]

What you should write depends on what you really need. What do your objects represent?

What do you expect

  $class=$_;
[download]

I think you mean to write

  my $class = shift;
[download]

  ABC->new();
[download]

my ($hashref, $arrayref, @array) = new();
print $hashref->{'a'};
print $array[0];
print $arrayref->[1];

sub new {
    my $hashref = {'a' => '1'};
    my @array = (2,3);
    my $arrayref = [4,5];
    return ($hashref, $arrayref, @array);
}
[download]

## $arrayref isn't defined!
my ($hashref, @array, $arrayref) = new();
print $hashref->{'a'};
print $array[0];
print $arrayref->[1];

sub new {
    my $hashref = {'a' => '1'};
    my @array = (2,3);
    my $arrayref = [4,5];
    return ($hashref, @array, $arrayref);
}
[download]