use strict;

my %house;
my $room;
while (<DATA>) {
    chomp;
    next unless $_; # skip blank lines

    if(/^\D/) { $room = $_ }
    else      { $house{$room}{$_}++ }
}

foreach my $room (keys %house) {
    print "$room:\n";
    print "width height quantity\n";
    map  { print "$_ $house{$room}{$_}\n"; }
      sort { $house{$room}{$b} <=> $house{$room}{$a} } 
      keys %{$house{$room}};
}

__DATA__
office 1

120 120

120 120

140 135

155 135

120 120

bedroom 2

100 75

100 75

120 180
[download]

bedroom 2:
width height quantity
100 75 2
120 180 1
office 1:
width height quantity
120 120 3
140 135 1
155 135 1
[download]

Well you probably want to read perlreftut but how about this:

my ($location, $h);
while(<DATA>){
    chomp;
    $location = $_ if m/^[a-zA-Z]/;
    next unless m/(\d+)\s+(\d+)/;
    $h->{$location}->{windows}++;
    $h->{$location}->{frames}->{"$1x$2"}++;
    $h->{$location}->{total_length}+= $1*2 + $2*2;
}
use Data::Dumper;
print Dumper $h;

my $fixed_cost_per_window = 100;
my $cost_by_material      = 0.5;
my $total;
for my $location( keys %$h ) {
    my $fixed = $h->{$location}->{windows} * $fixed_cost_per_window;
    my $materials = $h->{$location}->{total_length} * $cost_by_materia
+l;
    printf "%-10s\t%d windows \$%7.2f\tmaterials \$%7.2f\ttotal \$%7.2
+f\n", 
        $location, $h->{$location}->{windows}, $fixed, $materials, $fi
+xed+$materials;
    $total += $fixed+$materials;
}
    printf "\nTotal: \$%.2f\n", $total;

__DATA__
office 1

120 120

120 120

140 135

155 135

120 120

bedroom 2

100 75

100 75

120 180
[download]

This produces:

$VAR1 = {
          'bedroom 2' => {
                           'frames' => {
                                         '120x180' => '1',
                                         '100x75' => '2'
                                       },
                           'windows' => '3',
                           'total_length' => '1300'
                         },
          'office 1' => {
                          'frames' => {
                                        '155x135' => '1',
                                        '140x135' => '1',
                                        '120x120' => '3'
                                      },
                          'windows' => '5',
                          'total_length' => '2570'
                        }
        };
bedroom 2     3 windows $ 300.00    materials $ 650.00    total $ 950.
+00
office 1      5 windows $ 500.00    materials $1285.00    total $1785.
+00

Total: $2735.00
[download]

Ok, I'm thinking you want a multi-dimensional hash. Here's basically what I'm talking about:

   %windows = (
      "office 1"  => ("120 120" => 3,
                      "140 135" => 1,
                      "155 135" => 1),

      "bedroom 2" => ("100 75"  => 2,
                      "120 180" => 1),
   );
[download]

So in hash %windows, key "office 1" has a value which is a *reference* to an anonymous hash (a *reference* to an anonymous hash is created by the parenthesis), and that reference refers to the anonymous hash which has these key/value's:

   Key       Value
 -------     -----
 120 120       3
 140 135       1
 155 135       1
[download]

   foreach my($room, $measurements_hashref) (each %windows) {
      print "$room\n";
      print "width\theight\tquantity\n";
      foreach my($measurements, $count) (each %$measurements_hashref) 
+{
         print "$measurements $count\n";
      }
   }
[download]

HTH.

I'll to preface this with saying that the output is not EXACTLY in the format that you want...But it is readable, and the program does appear to work. I'm just a simple Perl hacker...With a little bit of elbow grease (which I don't necessarily know how to apply), this could become what you're looking for.

#!/usr/bin/perl -wT

use strict;
use Data::Dumper;

my $roomtype;
my $dim;
my $count;
my %output;

while (<DATA>) {
  chomp;

  # If the first character of the input is a letter, then we're on a n
+ew
  # room type
  if (/^[a-zA-Z]+/) {
    $roomtype = $_;
        $dim = undef;
  } else {
    $dim = join('_', split / /);
  }

  if (defined($roomtype) && defined($dim)) {
    my $room = $roomtype . '_' . $dim;

    if (defined($output{$room})) {
      my $cur = $output{$room};
      $cur++;
      $output{$room} = $cur;
    } else {
      $output{$room} = 1;
    }
  }
}

my $data = Data::Dumper->new([\%output], [qw/*output/]);

print $data->Dump;

__DATA__
office 1
120 120
120 120
140 135
155 135
120 120
bedroom 2
100 75
100 75
120 180
[download]

And the output:

$ ./window.pl
%output = (
            'bedroom 2_120_180' => 1,
            'office 1_120_120' => 3,
            'bedroom 2_100_75' => 2,
            'office 1_155_135' => 1,
            'office 1_140_135' => 1
          );
[download]

my %windows;

my $current_location;

while (<>) { # read from stdin
    chomp;
    if ( /^\d+\s+\d+/ ) {
        $current_location or die "bad input";
        $windows{$current_location}{$_}++;
    }
    else {
        $current_location = $_;
    }
}

for my $location ( sort keys %windows )
{
    print "\n$location\nwidth height quantity\n";
    for my $dimensions { sort keys %{ $windows{$location} } ) {
        print "$dimensions $windows{$location}{$dimensions}\n";
    }
}
[download]

use strict;
use warnings;

my (@arr, $ref);

while (<DATA>) {
    chomp;
    if (/^[a-zA-Z]/) { $arr[$#arr+1][0] = $_; }
    elsif (/^\d/) { $arr[$#arr][1]{$_}++; }
}
foreach (@arr) {
    print @$_[0] . "\n\n";
    print "width height quantity\n\n";
    $ref = @$_[1];
    for (sort {$ref->{$b} <=> $ref->{$a} or $a cmp $b} keys %$ref) {
        print "$_ " . $ref->{$_} . "\n\n";
    }
}

__DATA__
office 1

120 120

120 120

140 135

155 135

120 120

bedroom 2

100 75

100 75

120 180
[download]

$worksheet->Cells($count,1)->{Value} = "$location";

$worksheet->Cells($count,1)->{Value} = "$width";

$worksheet->Cells($count,2)->{Value} = "$height";

$worksheet->Cells($count,3)->{Value} = "$quantity";

etc

In addition, I am also wanting to specify a type of film used with a given location

I was thinking that I could use tab spacing between the location name and the film type

For example the text file will look like this

office 3 \t safetyfilm

100 120

100 120

135 125

bedroom 1 \t windowtint

125 125

125 125

Then i would also export the film type into Excel

$worksheet->Cells($count,2)->{Value} = "$film";

Or should i place the type of film into the text file another way

Thankyou all again

Thankyou again for all your wisdom

Why not just make the film another entry in the subhash? for example:



Office 1
    Film => 'something',
    '120 100' => 2
etc.
[download]



Then you have one per location, and you can easily separate it from the dimension counts by name.

--
Spring: Forces, Coiled Again!