You're very close. Here is one way to do it:

use strict;
use warnings;

my $string = 'This is "the search" string "that was" supplied';

my @quotes;

while( $string =~ s["(.*?)"][] )
{
    push( @quotes, $1 );
}

my @keys = split( ' ', $string );

use Data::Dumper;
print "Quotes:\n", Dumper( \@quotes );
print "Keys:\n", Dumper( \@keys );

output:

Quotes:
$VAR1 = [
          'the search',
          'that was'
        ];
Keys:
$VAR1 = [
          'This',
          'is',
          'string',
          'supplied'
        ];
[download]

I'm sure someone else will come up with a more clever way of doing it, perhaps with one of the Text modules, but this works with the data you supplied. If you need to handle escaped quotes, definitely consider one of the modules.

HTH

It is much more clean to use Text::ParseWords than regexp. For example:

use Text::ParseWords;
$_ ='1111  "222 222"   333 4444 55    666 77777';
print join(",", (quotewords('\s+', 0, $_))[0,1,2,4,5,6]);
[download]

Then do whatever you want on top of this.

$_ = 'This is "the search" string "that was" supplied';
while(/"(.*?)"|(\S+)/g) {
    if(defined $1) {
        push @quotes, $1;
    } else {
        push @keywords, $2;
    }
}
[download]

  my @quotes = $keyword =~ s/"([^"]*)?"//;
  my @keys = split(/ /, $keyword);
[download]

 
  my @keys =grep length, split(/ /, $keyword);
[download]

 
  my @keys = split(" ", $keyword);
[download]

$_ = 'This is "the search" string "that was" supplied';
my @quotes = (m/"(.*?)"/g); s/".*?"//g;
my @keys = split();
[download]

use strict;
use warnings;

my $time = time();
for (1..1000000) {
    $_ = 'This is "the search" string "that was" supplied';
    my @quotes = (m/"(.*?)"/g); s/".*?"//g;
    my @keys = split();
} 
print time() - $time;
[download]