my %hash = map { 
                    join(':', $_->{Computer}, 
                              $_->{Bulletin}, 
                              ( $_->{Product} || "" ), 
                              $_->{Status} 
                    ) => $_ 
                } @{GetQueryTable('all_records_for_report', 138)};
[download]

or

my %hash;
for ( @{GetQueryTable('all_records_for_report', 137)} ) {
    $hash{"$_->{Computer}:$_->{Bulletin}:"
            . ($_->{Product}||"") 
            . ":$_->{Status}"} = $_;
}
[download]

Well, the map-based approach puts the focus on the fact that you're populating %hash. Where you're getting the data from is secondary. The for-based approach puts the focus on the fact that you're doing something with each element in all_records_for_report. What you're doing with it is secondary.

mmmh...

Good point - I see, I won't get around some comments* :-(

update:
*comments to where the data comes from, because I think that part is secondary. Now I also know the why :-)

update2:

sub make_lookup {
    my %hash = map { my $hash = $_;
                    join(':', map { $hash->{$_} || "" 
                                } sort(keys(%{$_})) ) => $_ 
                } @_;

    return \%hash;
}

my $lookup = make_lookup(@{GetQueryTable('all_records_for_report', 138
+)});
[download]

Theres another distinction besides the ones already mentioned. The first one screams "I'm setting up %hash now for the first time!" the second one depending on where the my %hash; part is located may also be a merge operation. In other words one to me looks like an initialization and the other a merge or aggregation. For instance we may have multiple reports being returned and want to merge them together and for this purpose the first is unsuitable.

OTOH, if it is an initialization then I personally prefer the first style.

:-)

It's just you. ;-) Relax, you'll get over it.

But to return to the point brother FU brings up above, it's a question of what you want to emphasize. I think you're talking about how %hash gets populated (a terrible name for the variable, by the way; try to think of a better one), so I might even offer a hybrid:

my %hash;
for ( @{GetQueryTable('all_records_for_report', 137)} ) {
    $hash{ join(':', $_->{Computer}, 
                              $_->{Bulletin}, 
                              ( $_->{Product} || "" ), 
                              $_->{Status} ) }
          = $_;
}
[download]

As Gerry Sussman explained,

"The important thing about a program is that it's something you can show to people, and they can read it and they can learn something from it ..."

And now for something completely disgusting.

my %hash;
{
  local $; = ":";
  $hash{ @{$_}{qw(Computer
                  Bulletin)},
             $_->{Product}||"",
             $_->{Status} } = $_ for @{GetQueryTable('all_records_for_
+report', 138)};
}
[download]