You can do that by shuffling an array of names and coupling neighbors in the result. I've omitted the file I/O parts for clarity.

This imports an excellent shuffle() function, use List::Util 'shuffle'; This reads an array full of the names with numbers and dot stripped, and then strips newlines, too,

my @friends = map { (split /\./)[1] } <DATA>;
chomp @friends;
[download]

@friends = shuffle @friends;
my %couple = (@friends);
[download]

for (keys %couple) {
    print "$_ and $couple{$_} are partners\n";
}
[download]

__DATA__
1.bobby
2.jane
3.charleen
4.markus
5.gabriel
6.Alex
[download]

Perl data structures and the shuffle function make this a lot easier.

The typical approach would be to read the data into an array, shuffle it, then just pull off the elements (in this case pairs)

# simulate chomp( my @people = <FILE> );
my @people = qw( bobby jane charlen markus gabriel alex );
fisher_yates_shuffle(\@people);
printf "Pair %s %s\n", shift(@people),shift(@people) while @people;

sub fisher_yates_shuffle {
    my $array = shift;
    for (my $i = @$array; --$i; ) {
        my $j = int rand ($i+1);
        next if $i == $j;
        @$array[$i,$j] = @$array[$j,$i];
    }
}
[download]

# Read names, extracting what's after the dot and before the end of li
+ne
my @names = map /\.(.*)/, <DATA>;

# Shuffle the list
use List::Util 'shuffle';
@names = shuffle(@names);

# Print them out two by two
for (1..@names/2) {
  print "Group $_: $names[$_*2-2] and $names[$_*2-1] are partners\n";
}

__DATA__
1.bobby
2.jane
3.charleen
4.markus
5.gabriel
6.Alex
[download]

He he! But is it fair?

#! perl -slw
use strict;

local $, = ' ';

my @array;
splice @array, rand( @array ), 0, $_ for map{ /^..(.*$)/ } <DATA>;
my %partners = @array;

print %partners;

__DATA__
1.bobby
2.jane
3.charleen
4.markus
5.gabriel
6.Alex
[download]

Heh, this code is the most interesting of the lot since it *seems* wrong.

If the splice line had been

splice @array, rand(1+@array ), 0, $_ for map{ /^..(.*$)/ } <DATA>;
[download]

it would obviously have been fair. Now it seems to have a slight preference for left, so that makes you worry that e.g. maybe the last two elements don't get paired often enough. But that impression is wrong. The bias only causes the order inside one pair to be lopsided. The element inserted first becomes the last element in @array, and will remain last during the loop. The other n-1 elements will get a fair shuffle. So after pairing the result is fair, but the first element inserted will always be last in its pair.

Using splice to deconstruct the list, instead of to construct it:

# Read names, chop off numbers
my @names = map /\.(.*)/, <DATA>;

# Pair them up randomly
for (1..@names/2) {
  printf "Group $_: %s and %s are partners\n", splice(@names, rand(@na
+mes), 1)
  , splice(@names, rand(@names), 1);
}
[download]

Update: using Thospel's idea, one of the splices could be replaced with a simple shift:

  printf "Group $_: %s and %s are partners\n", shift(@names), splice(@
+names, rand(@names), 1);
[download]

---

Caution: Contents may have been coded under pressure.

1) When I execute the code, I don't get any output. That's because your function randomize has an endless loop.

while (@file_contents) {  $totalline++; }
[download]

Probably you wanted to say 'foreach', so that the function tells you the size of @file_contents. But then the sub shouldn't be called 'randomize'. As a side note, you get the size of the array simply with 'scalar(@file_contents)'.

2) The splice in sub compile_list takes not only person $ng out, but $ng persons begining at position $ng. Use 'splice(@file_contents,$ng,1);'

By the way, in this sub a 'while (@file_contents)' as main loop would have been better, since you are finished when @file_contents is empty.

3) in sub makegroups you select two adjacent names out of the list, but you increment $fark only by 1. Try it out, you will see that every name except the first will be printed twice.

Ok, that's what I found out. If there is still something wrong with the script, put in 'print' statements to show you what is going on. The first thing I did with your script was to insert code like

print "Position 1: @file_contents\n";
[download]

#!/usr/bin/perl -w
use strict;
use warnings;

my @people = map /\.(.*)/, <DATA>;
my $group = 1;
while (@people) {
    my $person1 = shift @people;
    my $pos = rand @people;
    my $person2 = $people[$pos];
    $people[$pos] = $people[-1];
    pop @people;
    printf "Group %d: %s and %s\n", $group++, $person1, $person2;
}

__DATA__
1.bobby
2.jane
3.charleen
4.markus
5.gabriel
6.Alex
[download]

use strict;
use warnings;

my ($x, $t);
my @n = map (/\.(.*)/, <DATA>);
for (0..($#n - 1)) {
    $x = int(rand() * ($#n - $_ + 1)) + $_;
    $t = $n[$x]; $n[$x] = $n[$_]; $n[$_] = $t;
}
for ($_ = 0; $_ < $#n; $_ += 2) {
    print "Group ".($_ / 2).": ".$n[$_]." and ".$n[$_+1]." are partner
+s\n";
}

__DATA__
1.bobby
2.jane
3.charleen
4.markus
5.gabriel
6.Alex
[download]