Re: map weirdness

What I want to achieve is that @b contains only the anonymous arrays which are found in @d, so i don't want the undef entries.

I can think of two major ways to obtain that result. One way would be if you leave map like it is but then use grep to filter out the undesired results:

@b = grep { ref $_ } @b;

The other way would be to change the map so that it only returns what you want in the first place, something along these lines...

my @b=map { 
    my $mapkey=$_; 
    map { 
       ($d[$mapkey]->[1] =~ /$a[$_]/)
          ? [@{$d[$mapkey]}] : ()
    } 0..$#a 
} 0..$#d;
[download]

(This code is all untested.)

The first approach is probably easier to follow, if you're new to Perl. The second approach is more direct, however, probably more efficient, and definitely more concise.

Of course, if I were writing the thing, I'd get rid of those array indices and map over the lists themselves...

my @b = map {
  my $d = $_;
  map { ($d->[1] =~ $$_) ? $d : () } @a
} @d
[download]

And if by =~ you really mean eq, we can simplify this further using a hash:

my %a = map { $_ => 1 } @a;
my @b = map {
  ($a{$_->[1]}) ? $_ : ()
} @d
[download]

Update: fixed a variable there.

Note that this last one doesn't do exactly the same thing. With your sample data set it gets the same result, and I *suspect* that it actually does what you want, but now if @a were to contain "BUS", @d would no longer get [4,"BUS2"], only [3,"BUS"]. But it exorcises the nested map, which makes it easier to follow and more efficient, if it does what you want.

"In adjectives, with the addition of inflectional endings, a changeable long vowel (Qamets or Tsere) in an open, propretonic syllable will reduce to Vocal Shewa. This type of change occurs when the open, pretonic syllable of the masculine singular adjective becomes propretonic with the addition of inflectional endings." — Pratico & Van Pelt, BBHG, p68

Comment on Re: map weirdness Select or Download Code

Replies are listed 'Best First'.
Re^2: map weirdness by revdiablo (Prior) on Dec 13, 2004 at 19:18 UTC
Excellent post, but I feel like I need to write in defense of the "first approach." Not only is it "easier to follow, if you're new to Perl," but I think it's easier to follow even if you're not new to Perl. In other words, it's simply clearer code. I say this because map and grep have fairly common, specific uses. Nearly anyone reading the code will immediately recognize `grep` as filtering the results. Shoving that logic into the `map` block fails to take advantage of that quick recognition. It may not seem like a lot, but these things add up.	[reply] [d/l] [select]
Re: map weirdness by jonadab (Parson) on Dec 14, 2004 at 14:50 UTC
I feel like I need to write in defense of the "first approach." Not only is it "easier to follow, if you're new to Perl," but I think it's easier to follow even if you're not new to Perl. Up to a point, I'd agree. Indeed, there's a reason I gave both approaches. Yet, you'll notice that it was when I went to the second approach that I felt the need to simplify the map (getting rid of the array indices -- this is Perl, not C), and then only after I'd done that did I really understand the logic of what was going on well enough to construct my fourth solution, which removes the nested map altogether. Having done that, we could combine it with the grep approach... `my %a = map { $_ => 1 } @a; my @b = grep { $a{$_->[1]} } @d` [download] This is perhaps clearest of all, if it does the right thing, which I suspect it does. I find it hard to believe that the original poster actually wanted the side-effect of matching substrings in this case. "In adjectives, with the addition of inflectional endings, a changeable long vowel (Qamets or Tsere) in an open, propretonic syllable will reduce to Vocal Shewa. This type of change occurs when the open, pretonic syllable of the masculine singular adjective becomes propretonic with the addition of inflectional endings." — Pratico & Van Pelt, BBHG, p68	[reply] [d/l]