#!/usr/bin/perl
use strict;
use warnings;

my $pid = open(CHILD, "-|");

if ($pid)
{
   # parent 
   print "parent got:\n";
   print while(<CHILD>);
   close CHILD; # this waits on child 
}
elsif ($pid == 0)
{
   # child 
   print "kid here!\n";
   exec '/bin/date' or die "Can't exec date $!\n";
}
else
{
   die "fork error: $!\n";
}
[download]

Take a look at IPC::Shareable. This seems like a perfect situation to use it. If that doesn't work, look at CPAN's other IPC modules -- there are lots of them.

use strict;

my @array = ();

pipe my $read, my $write or
    die "Cannot open pipe";

for(1..3) {
    defined(my $pid = fork) or die "Can't fork\n";

    if($pid) {
        next;  # Parent: continue loop
    }

        # Child
    pipe_send($write, "I'm process $$!");
    exit 0;
}

# Parent
for(1..3) {
    my $element = pipe_recv($read);
    push @array, $element;
}

print "array = @array\n";

##################################################
sub pipe_send {
##################################################
    my($fh, $message) = @_;

    my $bytes = sprintf "0x%08x", length($message);
    syswrite($fh, $bytes . $message);
}

##################################################
sub pipe_recv {
##################################################
    my($fh) = @_;

    die "Protocol corrupted" if
        sysread($fh, my $bytes, 10) != 10;
    $bytes = hex($bytes);

    my $data = "";
    while($bytes != 0) {
        my $read = sysread($fh, my $chunk, $bytes);
        last unless defined $read;
        $bytes -= $read; $data .= $chunk;
    }
    return $data;
}
[download]

Thank you so much everyone. I got it working now. I needed to figure this out because I'm working on a large complex script that polls the MAC-address table (CAM) of several switches on a large network, then consolidates the results into a database. Knowing how to make the polling processes run simultaneously (using the example above), my code will be much more efficient now instead of polling the switches one at a time. Thanks again, you all rock!

This is trivial using threads.

I said it was trivial:)

#! perl -slw
use strict;
use threads;
use threads::shared;

my @myarray : shared;
sub pid { lock @myarray; push @myarray, $_[ 0 ]; }
threads->new( \&pid, $_ )->detach for 1 .. 3;
sleep 2;
print "@myarray";
__END__
[23:30:52.15] P:\test>417163
1 2 3
[download]

---

Examine what is said, not who speaks.        The end of an era!

"But you should never overestimate the ingenuity of the sceptics to come up with a counter-argument." -Myles Allen
"Think for yourself!" - Abigail        "Time is a poor substitute for thought"--theorbtwo         "Efficiency is intelligent laziness." -David Dunham
"Memory, processor, disk in that order on the hardware side. Algorithm, algorithm, algorithm on the code side." - tachyon